Arduino UNO R4 - Joystick
In diesem Leitfaden lernen wir, wie man einen Joystick mit dem Arduino UNO R4 verwendet. Wir werden Folgendes behandeln:
- Wie ein Joystick funktioniert
- Wie man einen Joystick an den Arduino UNO R4 anschließt
- Wie man den Arduino UNO R4 programmiert, um Werte von einem Joystick auszulesen
- Wie man die vom Joystick gelesenen Werte in umsetzbare Werte umwandelt (z. B. XY-Koordinaten oder Richtungen für einen Motor)
Erforderliche Hardware
Oder Sie können die folgenden Kits kaufen:
| 1 | × | DIYables STEM V4 IoT Starter-Kit (Arduino enthalten) | |
| 1 | × | DIYables STEM V4B IoT Starter-Kit (Arduino enthalten) | |
| 1 | × | DIYables Sensor-Kit (18 Sensoren/Displays) |
Offenlegung: Einige der in diesem Abschnitt bereitgestellten Links sind Amazon-Affiliate-Links. Wir können eine Provision für Käufe erhalten, die über diese Links getätigt werden, ohne zusätzliche Kosten für Sie. Wir schätzen Ihre Unterstützung.
Über Joystick
Vielleicht haben Sie schon einen Joystick gesehen, der als Gamecontroller, als Spielzeugsteuerung oder sogar in großen Maschinen wie Baggersteuerungen verwendet wird.
Der Joystick besitzt zwei Potentiometer, die in einer quadratischen Anordnung angeordnet sind, sowie einen Druckknopf. Er liefert die folgenden Ausgänge:
- Ein Analogwert (von 0 bis 1023) für die horizontale Position (X-Koordinate)
- Ein Analogwert (von 0 bis 1023) für die vertikale Position (Y-Koordinate)
- Ein digitaler Zustand eines Tasters (HIGH oder LOW)
Wenn Sie zwei analoge Werte kombinieren, ergeben sie 2-D-Koordinaten. Diese Koordinaten sind zentriert, wenn der Joystick nicht bewegt wird. Sie können die tatsächliche Richtung dieser Koordinaten ganz einfach herausfinden, indem Sie einen Testcode ausführen, den wir im nächsten Abschnitt behandeln werden.
Einige Anwendungen verwenden möglicherweise alle drei Ausgänge, während andere nur einige von ihnen verwenden.
Pinbelegung
Ein Joystick verwendet fünf Pins.
- GND-Pin: mit GND (0 V) verbinden
- VCC-Pin: mit VCC (5 V) verbinden
- VRX-Pin: liefert einen analogen Wert für die horizontale Position (X-Koordinate).
- VRY-Pin: liefert einen analogen Wert für die vertikale Position (Y-Koordinate).
- SW-Pin: stammt vom Druckknopf des Joysticks. Er ist normalerweise offen. Durch einen Pull-up-Widerstand wird dieser Pin hoch, wenn er nicht gedrückt ist, und niedrig, wenn er gedrückt ist.
Wie es funktioniert
- Links/Rechts-Bewegung
- Wenn Sie den Joystick nach links oder rechts bewegen, ändert sich das elektrische Signal (Spannung) am VRX-Pin.
- Beim Bewegen nach links sinkt die Spannung auf 0 Volt.
- Beim Bewegen nach rechts erhöht sich die Spannung auf 5 Volt.
- Der Arduino liest diese Spannung ebenfalls aus und wandelt sie in eine Zahl zwischen 0 und 1023 um. 0 Volt entspricht also 0 und 5 Volt entspricht 1023.
- Hoch-/Runter-Bewegung
- Ebenso ändert das Bewegen des Joysticks nach oben oder unten die Spannung am VRY-Pin.
- Beim Bewegen nach oben sinkt die Spannung auf 0 Volt.
- Beim Bewegen nach unten erhöht sich die Spannung auf 5 Volt.
- Der Arduino liest diese Spannung ebenfalls aus und wandelt sie in eine Zahl zwischen 0 und 1023 um, genauso wie beim VRX-Pin.
- Kombinierte Bewegungen:
- Wenn Sie den Joystick in irgendeine Richtung bewegen (nicht nur rein links/rechts oder hoch/runter), ändert sich die Spannung am VRX-Pin und am VRY-Pin entsprechend seiner Position entlang jeder Achse.
- Drücken des Joysticks:
- Wenn Sie den Joystick nach unten drücken (wie das Drücken eines Knopfes), aktiviert sich im Joystick ein interner Knopf.
- Schließen Sie einen Pull-up-Widerstand an den SW-Pin an, ändert sich die Spannung an diesem Pin beim Drücken von 5 V auf 0 V.
- Der Arduino liest diese Änderung als digitales Signal aus und zeigt HIGH (5 V) an, wenn nicht gedrückt, und LOW (0 V), wenn gedrückt.
Zusammenfassend ändern sich beim Bewegen des Joysticks die Spannungen an VRX und VRY, die vom Arduino als Zahlen zwischen 0 und 1023 gelesen werden. Beim Drücken des Joysticks ändert sich die Spannung am SW-Pin, die vom Arduino als HIGH oder LOW gelesen wird.
Verdrahtungsdiagramm
Dieses Bild wurde mit Fritzing erstellt. Klicken Sie, um das Bild zu vergrößern.
Siehe Der beste Weg, den Arduino Uno R4 und andere Komponenten mit Strom zu versorgen.
Wie man für Joysticks programmiert
Der Joystick besteht aus zwei Komponenten: einem analogen Teil (X- und Y-Achse) und einem digitalen Teil (einem Druckknopf).
- Um die Werte für die X- und Y-Achsen abzulesen, verwenden Sie einfach die Funktion analogRead() am analogen Eingangspin.
int xValue = analogRead(A1);
int yValue = analogRead(A0);
- Für den digitalen Teil, der ein Druckknopf ist: Es ist einfach nur ein Knopf. Eine einfache und effektive Methode ist die Verwendung der ezButton-Bibliothek. Diese Bibliothek hilft, die Stabilität des Knopfes zu verwalten, und aktiviert außerdem ein internes System, um den Knopf stabil zu halten. Weitere Informationen finden Sie im Arduino UNO R4 - Knopf-Tutorial. Wir zeigen Ihnen, wie Sie den Code im nächsten Teil dieses Tutorials verwenden.
Nachdem wir die Messwerte von den analogen Pins erhalten haben, müssen wir sie möglicherweise in handhabbare Werte umwandeln. Der folgende Abschnitt enthält dazu Beispielcodes.
Arduino UNO R4 Quellcode
Hier sind Beispielcodes für Arduino UNO R4:
- Example code: holt analoge Werte vom Joystick
- Example code: holt analoge Werte und überprüft den Tastzustand am Joystick
- Example code: ändert analoge Werte in Befehle: MOVE_LEFT, MOVE_RIGHT, MOVE_UP, MOVE_DOWN
- Example code: wandelt analoge Werte in Winkel um, um zwei Servomotoren zu steuern (wie bei einer Schwenk-Neige-Kamera)
Liest analoge Werte vom Joystick
/*
* Dieser Arduino UNO R4 Code wurde von newbiely.de entwickelt
* Dieser Arduino UNO R4 Code wird der Öffentlichkeit ohne jegliche Einschränkung zur Verfügung gestellt.
* Für vollständige Anleitungen und Schaltpläne besuchen Sie bitte:
* https://newbiely.de/tutorials/arduino-uno-r4/arduino-uno-r4-joystick
*/
#define VRX_PIN A1 // The Arduino UNO R4 pin connected to VRX pin
#define VRY_PIN A0 // The Arduino UNO R4 pin connected to VRY pin
int xValue = 0; // To store value of the X axis
int yValue = 0; // To store value of the Y axis
void setup() {
Serial.begin(9600) ;
}
void loop() {
// read analog X and Y analog values
xValue = analogRead(VRX_PIN);
yValue = analogRead(VRY_PIN);
// print data to Serial Monitor on Arduino IDE
Serial.print("x = ");
Serial.print(xValue);
Serial.print(", y = ");
Serial.println(yValue);
delay(200);
}
Schnelle Schritte
Folgen Sie diesen Anweisungen Schritt für Schritt:
- Wenn dies Ihre erste Verwendung des Arduino UNO R4 WiFi/Minima ist, lesen Sie das Tutorial zur Einrichtung der Entwicklungsumgebung für Arduino UNO R4 WiFi/Minima in der Arduino IDE (BASE_URL/tutorials/arduino-uno-r4/arduino-uno-r4-software-installation).
- Verbinden Sie den Joystick gemäß dem bereitgestellten Diagramm mit dem Arduino UNO R4.
- Schließen Sie das Arduino UNO R4-Board über ein USB-Kabel an Ihren Computer an.
- Starten Sie die Arduino IDE auf Ihrem Computer.
- Wählen Sie das passende Arduino UNO R4-Board (z. B. Arduino UNO R4 WiFi) und den COM-Port aus.
- Kopieren Sie den obigen Code und öffnen Sie ihn in der Arduino IDE.
- Klicken Sie auf die Schaltfläche Hochladen in der Arduino IDE, um den Code auf Ihren Arduino UNO R4 hochzuladen.
- Bewegen Sie den Joystick ganz bis zum Rand und drehen Sie ihn dann in einer Kreisbewegung (im Uhrzeigersinn oder gegen den Uhrzeigersinn).
- Überprüfen Sie die Ergebnisse im Serial Monitor.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno R4 WiFi' on 'COM15')
New Line
9600 baud
- Beim Drehen des Joysticks behalte den Serial Monitor im Auge. Wenn der X-Wert 0 anzeigt, merke dir diese Position als links; das Gegenstück dazu ist rechts. Wenn der Y-Wert 0 ist, merke dir diese Position als oben; das Gegenstück dazu ist unten.
Liest analoge Werte aus und liest den Tastzustand eines Joysticks aus
/*
* Dieser Arduino UNO R4 Code wurde von newbiely.de entwickelt
* Dieser Arduino UNO R4 Code wird der Öffentlichkeit ohne jegliche Einschränkung zur Verfügung gestellt.
* Für vollständige Anleitungen und Schaltpläne besuchen Sie bitte:
* https://newbiely.de/tutorials/arduino-uno-r4/arduino-uno-r4-joystick
*/
#include <ezButton.h>
#define VRX_PIN A1 // The Arduino UNO R4 pin connected to VRX pin
#define VRY_PIN A0 // The Arduino UNO R4 pin connected to VRY pin
#define SW_PIN 2 // The Arduino UNO R4 pin connected to SW pin
ezButton button(SW_PIN);
int xValue = 0; // To store value of the X axis
int yValue = 0; // To store value of the Y axis
int bValue = 0; // To store value of the button
void setup() {
Serial.begin(9600) ;
button.setDebounceTime(50); // set debounce time to 50 milliseconds
}
void loop() {
button.loop(); // MUST call the loop() function first
// read analog X and Y analog values
xValue = analogRead(VRX_PIN);
yValue = analogRead(VRY_PIN);
// Read the button value
bValue = button.getState();
if (button.isPressed()) {
Serial.println("The button is pressed");
// TODO do something here
}
if (button.isReleased()) {
Serial.println("The button is released");
// TODO do something here
}
// print data to Serial Monitor on Arduino IDE
Serial.print("x = ");
Serial.print(xValue);
Serial.print(", y = ");
Serial.print(yValue);
Serial.print(" : button = ");
Serial.println(bValue);
}
Schnelle Schritte
- Gehen Sie zum Bibliotheken-Symbol auf der linken Seite der Arduino IDE.
- Suchen Sie nach “ezButton” und finden Sie die Button-Bibliothek von ArduinoGetStarted.com.
- Drücken Sie die Install-Taste, um die ezButton-Bibliothek hinzuzufügen.
- Kopiere den Code und öffne ihn in der Arduino IDE.
- Klicke auf die Upload-Schaltfläche in der Arduino IDE, um den Code auf den Arduino UNO R4 hochzuladen.
- Bewege den Joystick-Stick nach links, rechts, oben oder unten.
- Drücke den oberen Teil des Joysticks nach unten.
- Überprüfe die Ergebnisse im Serial Monitor.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno R4 WiFi' on 'COM15')
New Line
9600 baud
Konvertiert einen analogen Wert in Befehle zum Bewegen nach LINKS/RECHTS/OBEN/UNTEN
/*
* Dieser Arduino UNO R4 Code wurde von newbiely.de entwickelt
* Dieser Arduino UNO R4 Code wird der Öffentlichkeit ohne jegliche Einschränkung zur Verfügung gestellt.
* Für vollständige Anleitungen und Schaltpläne besuchen Sie bitte:
* https://newbiely.de/tutorials/arduino-uno-r4/arduino-uno-r4-joystick
*/
#define VRX_PIN A1 // The Arduino UNO R4 pin connected to VRX pin
#define VRY_PIN A0 // The Arduino UNO R4 pin connected to VRY pin
#define LEFT_THRESHOLD 400
#define RIGHT_THRESHOLD 800
#define UP_THRESHOLD 400
#define DOWN_THRESHOLD 800
#define COMMAND_NO 0x00
#define COMMAND_LEFT 0x01
#define COMMAND_RIGHT 0x02
#define COMMAND_UP 0x04
#define COMMAND_DOWN 0x08
int xValue = 0 ; // To store value of the X axis
int yValue = 0 ; // To store value of the Y axis
int command = COMMAND_NO;
void setup() {
Serial.begin(9600) ;
}
void loop() {
// read analog X and Y analog values
xValue = analogRead(VRX_PIN);
yValue = analogRead(VRY_PIN);
// converts the analog value to commands
// reset commands
command = COMMAND_NO;
// check left/right commands
if (xValue < LEFT_THRESHOLD)
command = command | COMMAND_LEFT;
else if (xValue > RIGHT_THRESHOLD)
command = command | COMMAND_RIGHT;
// check up/down commands
if (yValue < UP_THRESHOLD)
command = command | COMMAND_UP;
else if (yValue > DOWN_THRESHOLD)
command = command | COMMAND_DOWN;
// NOTE: AT A TIME, THERE MAY BE NO COMMAND, ONE COMMAND OR TWO COMMANDS
// print command to serial and process command
if (command & COMMAND_LEFT) {
Serial.println("COMMAND LEFT");
// TODO: add your task here
}
if (command & COMMAND_RIGHT) {
Serial.println("COMMAND RIGHT");
// TODO: add your task here
}
if (command & COMMAND_UP) {
Serial.println("COMMAND UP");
// TODO: add your task here
}
if (command & COMMAND_DOWN) {
Serial.println("COMMAND DOWN");
// TODO: add your task here
}
}
Schnelle Schritte
- Kopieren Sie den obigen Code und öffnen Sie ihn mit der Arduino IDE.
- Klicken Sie in der Arduino IDE auf die Upload-Schaltfläche, um den Code auf Arduino UNO R4 hochzuladen.
- Bewegen Sie den Daumenstick nach links, rechts, oben, unten oder in eine andere Richtung.
- Überprüfen Sie die Ergebnisse im seriellen Monitor.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno R4 WiFi' on 'COM15')
New Line
9600 baud
※ Notiz:
Manchmal gibt es möglicherweise keinen Befehl, einen Befehl oder zwei Befehle gleichzeitig (zum Beispiel UP und LEFT zusammen).
Konvertiert analoge Werte in Winkel, um zwei Servomotoren zu steuern
Sie finden Informationen zum Tutorial Arduino UNO R4 - Joystick-Steuerung des Servomotors.
Video Tutorial
Wir erwägen die Erstellung von Video-Tutorials. Wenn Sie Video-Tutorials für wichtig halten, abonnieren Sie bitte unseren YouTube-Kanal , um uns zu motivieren, die Videos zu erstellen.
Die folgende Video-Demo verwendet den folgenden Code:
/*
* Dieser Arduino UNO R4 Code wurde von newbiely.de entwickelt
* Dieser Arduino UNO R4 Code wird der Öffentlichkeit ohne jegliche Einschränkung zur Verfügung gestellt.
* Für vollständige Anleitungen und Schaltpläne besuchen Sie bitte:
* https://newbiely.de/tutorials/arduino-uno-r4/arduino-uno-r4-joystick
*/
#include "Arduino_LED_Matrix.h"
// Pin definitions
#define PIN_VRX A1
#define PIN_VRY A0
#define PIN_SW 2
#define PIN_BUZZER 8
// Matrix display dimensions
#define MATRIX_WIDTH 12
#define MATRIX_HEIGHT 8
#define MAX_SNAKE_LENGTH 96
// Snake movement direction
enum Direction {
UP,
DOWN,
LEFT,
RIGHT
};
// Game state machine
enum GameState {
START_BOOT, // Initial boot screen scrolling "DIYables"
PLAYING, // Active gameplay
GAME_OVER // Game over score display
};
GameState currentState = START_BOOT;
ArduinoLEDMatrix matrix;
uint8_t frame[8][12];
// Snake properties
int snakeX[MAX_SNAKE_LENGTH];
int snakeY[MAX_SNAKE_LENGTH];
int snakeLength = 3;
int score = 0;
Direction dir = RIGHT;
Direction nextDir = RIGHT;
// Food coordinates
int foodX = 0;
int foodY = 0;
// Movement timing
unsigned long lastMoveTime = 0;
int moveInterval = 250;
// Text scrolling timing
int startTextX = 12;
int scoreTextX = 12;
unsigned long lastScrollTime = 0;
const int SCROLL_INTERVAL = 75;
// Physics particle structure for 3s fall effect
struct Particle {
float x;
float y;
float vx;
float vy;
bool active;
};
// Function prototypes
void resetGame();
void handleInput();
void updateGameLogic();
void renderGame();
void spawnFood();
void renderText(String text, int xOffset);
uint8_t getCharCol(char c, int col);
void playShootingStarEffect();
void playEatSound();
void playStartSound();
bool isButtonPressed();
void clearFrame();
void setup() {
pinMode(PIN_SW, INPUT_PULLUP);
pinMode(PIN_BUZZER, OUTPUT);
matrix.begin();
randomSeed(analogRead(A2));
}
void loop() {
switch (currentState) {
case START_BOOT:
// Show "DIYables" only on initial power-up
if (millis() - lastScrollTime >= SCROLL_INTERVAL) {
lastScrollTime = millis();
renderText("DIYables", startTextX);
startTextX--;
if (startTextX < -36) {
startTextX = 12;
}
}
if (isButtonPressed()) {
resetGame();
playStartSound();
currentState = PLAYING;
}
break;
case PLAYING:
handleInput();
updateGameLogic();
renderGame();
break;
case GAME_OVER:
// Display score ("Score: X")
if (millis() - lastScrollTime >= SCROLL_INTERVAL) {
lastScrollTime = millis();
String scoreStr = "Score: " + String(score);
renderText(scoreStr, scoreTextX);
scoreTextX--;
int strLen = scoreStr.length() * 4;
if (scoreTextX < -strLen) {
scoreTextX = 12;
}
}
// Press button to restart game directly
if (isButtonPressed()) {
resetGame();
playStartSound();
currentState = PLAYING;
}
break;
}
}
// Read Joystick axes independently for accurate 4-way directional control
void handleInput() {
int xVal = analogRead(PIN_VRX);
int yVal = analogRead(PIN_VRY);
int dx = xVal - 512;
int dy = yVal - 512;
// Prioritize axis with stronger deflection
if (abs(dx) > abs(dy)) {
if (dx < -200 && dir != RIGHT) nextDir = LEFT;
else if (dx > 200 && dir != LEFT) nextDir = RIGHT;
} else {
if (dy < -200 && dir != DOWN) nextDir = UP;
else if (dy > 200 && dir != UP) nextDir = DOWN;
}
}
// 3.0-second shooting star fall effect
void playShootingStarEffect() {
const int MAX_PARTICLES = 45;
Particle particles[MAX_PARTICLES];
int pCount = 0;
// Convert active LEDs (snake body and food) into free-falling particles
for (int r = 0; r < MATRIX_HEIGHT; r++) {
for (int c = 0; c < MATRIX_WIDTH; c++) {
if (frame[r][c] == 1 && pCount < 25) {
particles[pCount].x = c;
particles[pCount].y = r;
particles[pCount].vx = (float)random(-15, 15) / 100.0;
particles[pCount].vy = (float)random(-20, 5) / 100.0;
particles[pCount].active = true;
pCount++;
}
}
}
unsigned long startTime = millis();
unsigned long lastSpawn = 0;
// 3-second physics simulation loop
while (millis() - startTime < 3000) {
clearFrame();
unsigned long elapsedTime = millis() - startTime;
// Spawn additional falling star trails from top during the first 2.2 seconds
if (elapsedTime < 2200 && millis() - lastSpawn > 80 && pCount < MAX_PARTICLES) {
lastSpawn = millis();
particles[pCount].x = random(0, MATRIX_WIDTH);
particles[pCount].y = -random(1, 4);
particles[pCount].vx = (float)random(-5, 5) / 100.0;
particles[pCount].vy = (float)random(10, 30) / 100.0;
particles[pCount].active = true;
pCount++;
}
// Update particle positions
for (int i = 0; i < pCount; i++) {
if (!particles[i].active) continue;
particles[i].x += particles[i].vx;
particles[i].y += particles[i].vy;
particles[i].vy += 0.04; // Gravity acceleration
int px = (int)round(particles[i].x);
int py = (int)round(particles[i].y);
// Draw particle
if (py >= 0 && py < MATRIX_HEIGHT && px >= 0 && px < MATRIX_WIDTH) {
frame[py][px] = 1;
}
// Draw particle trail if falling rapidly
int tailY = py - 1;
if (tailY >= 0 && tailY < MATRIX_HEIGHT && px >= 0 && px < MATRIX_WIDTH && particles[i].vy > 0.3) {
frame[tailY][px] = 1;
}
// Deactivate particle once below screen
if (py >= MATRIX_HEIGHT + 3) {
particles[i].active = false;
}
}
matrix.renderBitmap(frame, 8, 12);
// Decreasing pitch sound from 1200Hz to 100Hz synchronized over 3 seconds
int soundFreq = 1200 - (int)((elapsedTime / 3000.0) * 1100);
if (soundFreq > 100) {
tone(PIN_BUZZER, soundFreq, 30);
}
delay(35);
}
noTone(PIN_BUZZER);
clearFrame();
matrix.renderBitmap(frame, 8, 12);
}
// 3x5 bitmap font data
uint8_t getCharCol(char c, int col) {
switch (c) {
// "DIYables" characters
case 'D': return (col==0)?0x1F:(col==1)?0x11:0x0E;
case 'I': return (col==0)?0x11:(col==1)?0x1F:0x11;
case 'Y': return (col==0)?0x03:(col==1)?0x1C:0x03;
case 'a': return (col==0)?0x0C:(col==1)?0x12:0x1E;
case 'b': return (col==0)?0x1F:(col==1)?0x14:0x08;
case 'l': return (col==0)?0x11:(col==1)?0x1F:0x10;
case 'e': return (col==0)?0x0C:(col==1)?0x16:0x14;
case 's': return (col==0)?0x14:(col==1)?0x16:0x0A;
// "Score:" characters
case 'S': return (col==0)?0x12:(col==1)?0x15:0x09;
case 'c': return (col==0)?0x0C:(col==1)?0x12:0x12;
case 'o': return (col==0)?0x0C:(col==1)?0x12:0x0C;
case 'r': return (col==0)?0x1E:(col==1)?0x04:0x02;
case ':': return (col==0)?0x00:(col==1)?0x0A:0x00;
case ' ': return 0x00;
// Digits 0 - 9
case '0': return (col==0)?0x0E:(col==1)?0x11:0x0E;
case '1': return (col==0)?0x12:(col==1)?0x1F:0x10;
case '2': return (col==0)?0x19:(col==1)?0x15:0x12;
case '3': return (col==0)?0x11:(col==1)?0x15:0x0A;
case '4': return (col==0)?0x07:(col==1)?0x04:0x1F;
case '5': return (col==0)?0x17:(col==1)?0x15:0x09;
case '6': return (col==0)?0x0E:(col==1)?0x15:0x09;
case '7': return (col==0)?0x19:(col==1)?0x05:0x03;
case '8': return (col==0)?0x0A:(col==1)?0x15:0x0A;
case '9': return (col==0)?0x12:(col==1)?0x15:0x0E;
default: return 0x00;
}
}
// Render string to LED matrix frame
void renderText(String text, int xOffset) {
clearFrame();
int curX = xOffset;
int topY = 1;
for (int i = 0; i < text.length(); i++) {
char ch = text.charAt(i);
for (int col = 0; col < 3; col++) {
int screenX = curX + col;
if (screenX >= 0 && screenX < MATRIX_WIDTH) {
uint8_t colData = getCharCol(ch, col);
for (int row = 0; row < 5; row++) {
if ((colData >> row) & 1) {
frame[topY + row][screenX] = 1;
}
}
}
}
curX += 4;
}
matrix.renderBitmap(frame, 8, 12);
}
// Snake game logic update
void updateGameLogic() {
if (millis() - lastMoveTime < moveInterval) return;
lastMoveTime = millis();
dir = nextDir;
int newHeadX = snakeX[0];
int newHeadY = snakeY[0];
switch (dir) {
case UP: newHeadY--; break;
case DOWN: newHeadY++; break;
case LEFT: newHeadX--; break;
case RIGHT: newHeadX++; break;
}
// Wall collision -> Game Over
if (newHeadX < 0 || newHeadX >= MATRIX_WIDTH || newHeadY < 0 || newHeadY >= MATRIX_HEIGHT) {
playShootingStarEffect();
scoreTextX = 12;
currentState = GAME_OVER;
return;
}
// Self-collision -> Game Over
for (int i = 0; i < snakeLength; i++) {
if (snakeX[i] == newHeadX && snakeY[i] == newHeadY) {
playShootingStarEffect();
scoreTextX = 12;
currentState = GAME_OVER;
return;
}
}
bool ateFood = (newHeadX == foodX && newHeadY == foodY);
if (ateFood) {
snakeLength++;
score++;
playEatSound();
if (moveInterval > 100) {
moveInterval -= 5;
}
}
for (int i = snakeLength - 1; i > 0; i--) {
snakeX[i] = snakeX[i - 1];
snakeY[i] = snakeY[i - 1];
}
snakeX[0] = newHeadX;
snakeY[0] = newHeadY;
if (ateFood) {
spawnFood();
}
}
void renderGame() {
clearFrame();
frame[foodY][foodX] = 1;
for (int i = 0; i < snakeLength; i++) {
frame[snakeY[i]][snakeX[i]] = 1;
}
matrix.renderBitmap(frame, 8, 12);
}
void spawnFood() {
bool onSnake;
do {
onSnake = false;
foodX = random(0, MATRIX_WIDTH);
foodY = random(0, MATRIX_HEIGHT);
for (int i = 0; i < snakeLength; i++) {
if (snakeX[i] == foodX && snakeY[i] == foodY) {
onSnake = true;
break;
}
}
} while (onSnake);
}
void resetGame() {
snakeLength = 3;
score = 0;
dir = RIGHT;
nextDir = RIGHT;
moveInterval = 250;
snakeX[0] = 4; snakeY[0] = 3;
snakeX[1] = 3; snakeY[1] = 3;
snakeX[2] = 2; snakeY[2] = 3;
spawnFood();
}
bool isButtonPressed() {
static bool lastState = HIGH;
bool state = digitalRead(PIN_SW);
if (lastState == HIGH && state == LOW) {
delay(50);
lastState = state;
return true;
}
lastState = state;
return false;
}
void clearFrame() {
memset(frame, 0, sizeof(frame));
}
void playEatSound() {
tone(PIN_BUZZER, 1200, 60);
}
void playStartSound() {
tone(PIN_BUZZER, 440, 80); delay(90);
tone(PIN_BUZZER, 554, 80); delay(90);
tone(PIN_BUZZER, 659, 120); delay(120);
}