Arduino Nano ESP32 – Drehencoder
In diesem Leitfaden lernen Sie, wie Sie den Drehencoder mit dem Arduino Nano ESP32 verwenden. Hier erfahren Sie, was wir lernen werden:
- Welche Unterschiede gibt es zwischen einem Drehencoder und einem Potentiometer?
- Wie der Drehencoder funktioniert.
- Wie man den Drehencoder an den Arduino Nano ESP32 anschließt.
- Wie man Code für den Arduino Nano ESP32 schreibt, um die Richtung und Position vom Drehencoder ohne Interrupt auszulesen.
- Wie man Code für den Arduino Nano ESP32 schreibt, um die Richtung und Position vom Drehencoder mit Interrupt auszulesen.
Erforderliche Hardware
Oder Sie können die folgenden Kits kaufen:
| 1 | × | DIYables Sensor-Kit (30 Sensoren/Displays) | |
| 1 | × | DIYables Sensor-Kit (18 Sensoren/Displays) |
Offenlegung: Einige der in diesem Abschnitt bereitgestellten Links sind Amazon-Affiliate-Links. Wir können eine Provision für Käufe erhalten, die über diese Links getätigt werden, ohne zusätzliche Kosten für Sie. Wir schätzen Ihre Unterstützung.
Über Drehencoder
Ein Drehknopf, wie bei einem Radio, kann Signale senden, die in Elektrizität umgewandelt werden. Er hilft uns zu wissen, wie weit er gedreht wurde und wo er positioniert ist. Es gibt zwei Haupttypen:
- Inkrementalencoder: Dieser Typ verwendet schnelle Signale, um zu messen, wie stark sich etwas in seiner Position verändert hat.
- Absolutencoder: Dieser Typ liefert für jeden Ort einen Geheimcode, der uns hilft zu ermitteln, wo sich etwas befindet, auch wenn die Stromversorgung ausfällt.
Diese Lektion befasst sich hauptsächlich mit dem ersten Typ, dem inkrementellen Encoder.
Pinbelegung des Drehencoder-Moduls
Ein Drehencoder-Modul hat vier Pins:
- CLK-Pin (Ausgang A): ist der Hauptimpuls, der uns sagt, wie viel Drehung erfolgt ist. Immer wenn Sie den Knopf in eine der Richtungen um eine Rastung (Klick) drehen, gibt der CLK-Pin ein Signal aus, das einen vollständigen Zyklus abschließt (LOW → HIGH → LOW).
- DT-Pin (Ausgang B): funktioniert wie der CLK-Pin, gibt jedoch ein Signal aus, das dem CLK-Signal um 90 Grad hinterherhinkt. Es hilft uns dabei, die Drehrichtung (im Uhrzeigersinn oder gegen den Uhrzeigersinn) zu bestimmen.
- SW-Pin: kommt vom Encoderknopf. Er ist normalerweise geöffnet. Wenn wir an diesen Pin einen Pull-up-Widerstand anschließen, ist der SW-Pin HIGH, wenn der Knopf nicht gedrückt ist, und LOW, wenn er gedrückt wird.
- VCC-Pin (+): muss mit VCC verbunden werden (zwischen 3,3 und 5 Volt).
- GND-Pin: muss mit GND (0 V) verbunden werden.
Drehencoder im Vergleich zu Potentiometern
Man könnte den Drehencoder mit dem Potentiometer verwechseln, aber sie sind unterschiedliche Bauteile. Hier ist ein Vergleich zwischen ihnen:
- Der Drehencoder ist wie die moderne Version eines Potentiometers, aber er kann mehr tun.
- Der Drehencoder kann sich eine vollständige Runde drehen, ohne anzuhalten, während das Potentiometer nur etwa drei Viertel des Kreises drehen kann.
- Der Drehencoder erzeugt Impulse, während das Potentiometer die analoge Spannung ausgibt.
- Der Drehencoder ist praktisch, wenn man nur herausfinden muss, wie weit sich der Drehknopf bewegt hat, nicht genau, wo er sich befindet. Das Potentiometer ist nützlich, wenn man wirklich genau wissen muss, wo sich ein Drehknopf befindet.
Wie ein Drehencoder funktioniert
Im Encoder gibt es eine kleine Scheibe mit Schlitzen, die an einen Pin namens C angeschlossen ist und als gemeinsamer Massepunkt dient. Du hast zwei weitere Pins, A und B.
- Wenn Sie den Knopf drehen, berühren die Pins A und B den gemeinsamen Massepin C, aber die Reihenfolge, in der sie ihn berühren, hängt davon ab, in welche Richtung Sie den Knopf drehen (im Uhrzeigersinn oder gegen den Uhrzeigersinn).
- Diese Berührungen erzeugen zwei Signale. Sie unterscheiden sich im Timing, weil ein Pin die Masse berührt, bevor der andere dies tut. Diese Signale sind um 90 Grad zueinander versetzt, was Quadraturkodierung genannt wird.
- Wenn Sie den Knopf im Uhrzeigersinn drehen, berührt Pin A die Masse, bevor Pin B dies tut. Wenn Sie jedoch gegen den Uhrzeigersinn drehen, trifft Pin B zuerst die Masse, bevor Pin A dies tut.
- Indem man überprüft, wann jeder Pin die Masse berührt oder wieder verlässt, kann man feststellen, in welche Richtung sich der Knopf dreht. Dies tun wir, indem wir prüfen, was mit Pin B passiert, wenn Pin A sich ändert.
Wenn A seinen Zustand von LOW auf HIGH ändert:
- Wenn B HIGH ist, wird der Drehknopf gegen den Uhrzeigersinn gedreht.
- Wenn B LOW ist, wird der Drehknopf im Uhrzeigersinn gedreht.
※ Notiz:
Pin A und Pin B sind mit den CLK- und DT-Pins verbunden. Je nach Hersteller kann jedoch die Reihenfolge unterschiedlich sein. Die unten angegebenen Codes sind mit dem Drehencoder von DIYables getestet worden.
Wie man einen Drehencoder programmiert
- Arduino Nano ESP32 liest das Signal vom CLK-Pin
- Wenn sich der Zustand von LOW nach HIGH ändert, liest der Arduino Nano ESP32 den Zustand des DT-Pins.
- Wenn der DT-Pin HIGH ist, wird der Knopf gegen den Uhrzeigersinn gedreht; der Arduino Nano ESP32 erhöht den Zähler um 1
- Wenn der DT-Pin LOW ist, wird der Knopf im Uhrzeigersinn gedreht; der Arduino Nano ESP32 verringert den Zähler um 1
Verdrahtungsdiagramm
Dieses Bild wurde mit Fritzing erstellt. Klicken Sie, um das Bild zu vergrößern.
Arduino Nano ESP32 Code – Drehencoder
Der unten stehende Arduino Nano ESP32-Code führt Folgendes aus:
- Ermittelt die Richtung und den Umfang der Drehung des Drehencoders.
- Falls der Knopf im Uhrzeigersinn um eine Rastung (Klick) gedreht wird, erhöhe den Zähler um eins.
- Falls der Knopf gegen den Uhrzeigersinn um eine Rastung (Klick) gedreht wird, verringere den Zähler um eins.
- Erfasst, ob der Knopf gedrückt wird.
/*
* Dieser Arduino Nano ESP32 Code wurde von newbiely.de entwickelt
* Dieser Arduino Nano ESP32 Code wird der Öffentlichkeit ohne jegliche Einschränkung zur Verfügung gestellt.
* Für vollständige Anleitungen und Schaltpläne besuchen Sie bitte:
* https://newbiely.de/tutorials/arduino-nano-esp32/arduino-nano-esp32-rotary-encoder
*/
#include <ezButton.h> // The library to use for SW pin
#define CLK_PIN D2 // The Arduino Nano ESP32 pin D2 connected to the rotary encoder's CLK pin
#define DT_PIN D3 // The Arduino Nano ESP32 pin D3 connected to the rotary encoder's DT pin
#define SW_PIN D4 // The Arduino Nano ESP32 pin D4 connected to the rotary encoder's SW pin
#define DIRECTION_CW 0 // clockwise direction
#define DIRECTION_CCW 1 // counter-clockwise direction
int counter = 0;
int direction = DIRECTION_CW;
int CLK_state;
int prev_CLK_state;
ezButton button(SW_PIN); // create ezButton object for pin 7;
void setup() {
Serial.begin(9600);
// Configure encoder pins as inputs
pinMode(CLK_PIN, INPUT);
pinMode(DT_PIN, INPUT);
button.setDebounceTime(50); // set debounce time to 50 milliseconds
// read the initial state of the rotary encoder's CLK pin
prev_CLK_state = digitalRead(CLK_PIN);
}
void loop() {
button.loop(); // MUST call the loop() function first
// read the current state of the rotary encoder's CLK pin
CLK_state = digitalRead(CLK_PIN);
// If the state of CLK is changed, then pulse occurred
// React to only the rising edge (from LOW to HIGH) to avoid double count
if (CLK_state != prev_CLK_state && CLK_state == HIGH) {
// if the DT state is HIGH
// The encoder is rotating in counter-clockwise direction => decrease the counter
if (digitalRead(DT_PIN) == HIGH) {
counter--;
direction = DIRECTION_CCW;
} else {
// The encoder is rotating in clockwise direction => increase the counter
counter++;
direction = DIRECTION_CW;
}
Serial.print("Rotary Encoder:: direction: ");
if (direction == DIRECTION_CW)
Serial.print("Clockwise");
else
Serial.print("Counter-clockwise");
Serial.print(" - count: ");
Serial.println(counter);
}
// save last CLK state
prev_CLK_state = CLK_state;
if (button.isPressed()) {
Serial.println("The button is pressed");
}
}
Zur Vereinfachung des Codes für die Entprellung von Tasten wird die ezButton-Bibliothek verwendet.
Schnelle Schritte
Wenn Sie Arduino Nano ESP32 zum ersten Mal verwenden, sehen Sie sich wie man die Umgebung für Arduino Nano ESP32 in der Arduino IDE einrichtet.
- Installieren Sie die ezButton-Bibliothek in der Arduino IDE.
- Kopieren Sie den obigen Code und öffnen Sie ihn in der Arduino IDE
- Klicken Sie in der Arduino IDE auf die Hochladen-Schaltfläche, um den Code auf den Arduino Nano ESP32 hochzuladen
- Drehen Sie den Drehknopf im Uhrzeigersinn, danach gegen den Uhrzeigersinn
- Drücken Sie den Knopf
- Schauen Sie sich das Ergebnis im seriellen Monitor an.
COM6
Rotary Encoder:: direction: CLOCKWISE - count: 1
Rotary Encoder:: direction: CLOCKWISE - count: 2
Rotary Encoder:: direction: CLOCKWISE - count: 3
Rotary Encoder:: direction: CLOCKWISE - count: 4
Rotary Encoder:: direction: CLOCKWISE - count: 5
Rotary Encoder:: direction: ANTICLOCKWISE - count: 4
Rotary Encoder:: direction: ANTICLOCKWISE - count: 3
Rotary Encoder:: direction: ANTICLOCKWISE - count: 2
Rotary Encoder:: direction: ANTICLOCKWISE - count: 1
Rotary Encoder:: direction: ANTICLOCKWISE - count: 0
The button is pressed
Autoscroll
Clear output
9600 baud
Newline
Code-Erklärung
Schau dir die Zeilenkommentare im Code an.
Arduino Nano ESP32 Code – Drehencoder mit Interrupt
Im vorherigen Code kann die Verwendung von Polling, um den Zustand des Pins kontinuierlich zu überwachen, Ressourcen des Arduino Nano ESP32 verschwenden und zu verpassten Zählungen führen, wenn die Ausführung anderer Codeabschnitte langsam ist.
Eine effektive Lösung besteht darin, den Interrupt zu nutzen, wodurch die Notwendigkeit des Pollings entfällt. Dies ermöglicht dem Arduino Nano ESP32, andere Aufgaben auszuführen, ohne Zählwerte zu verpassen. Unten ist der Arduino Nano ESP32-Code, der den Interrupt verwendet, um die Richtung und Position vom Drehencoder auszulesen.
/*
* Dieser Arduino Nano ESP32 Code wurde von newbiely.de entwickelt
* Dieser Arduino Nano ESP32 Code wird der Öffentlichkeit ohne jegliche Einschränkung zur Verfügung gestellt.
* Für vollständige Anleitungen und Schaltpläne besuchen Sie bitte:
* https://newbiely.de/tutorials/arduino-nano-esp32/arduino-nano-esp32-rotary-encoder
*/
#include <ezButton.h> // The library to use for SW pin
#define CLK_PIN D2 // The Arduino Nano ESP32 pin D2 connected to the rotary encoder's CLK pin
#define DT_PIN D3 // The Arduino Nano ESP32 pin D3 connected to the rotary encoder's DT pin
#define SW_PIN D4 // The Arduino Nano ESP32 pin D4 connected to the rotary encoder's SW pin
#define DIRECTION_CW 0 // clockwise direction
#define DIRECTION_CCW 1 // counter-clockwise direction
volatile int counter = 0;
volatile int direction = DIRECTION_CW;
volatile unsigned long last_time; // for debouncing
int prev_counter;
ezButton button(SW_PIN); // create ezButton object for pin 7;
void IRAM_ATTR ISR_encoder() {
if ((millis() - last_time) < 50) // debounce time is 50ms
return;
if (digitalRead(DT_PIN) == HIGH) {
// The encoder is rotating in counter-clockwise direction => decrease the counter
counter--;
direction = DIRECTION_CCW;
} else {
// The encoder is rotating in clockwise direction => increase the counter
counter++;
direction = DIRECTION_CW;
}
last_time = millis();
}
void setup() {
Serial.begin(9600);
// Configure encoder pins as inputs
pinMode(CLK_PIN, INPUT);
pinMode(DT_PIN, INPUT);
button.setDebounceTime(50); // set debounce time to 50 milliseconds
// use interrupt for CLK pin is enough
// call ISR_encoder() when CLK pin changes from LOW to HIGH
attachInterrupt(digitalPinToInterrupt(CLK_PIN), ISR_encoder, RISING);
}
void loop() {
button.loop(); // MUST call the loop() function first
if (prev_counter != counter) {
Serial.print("Rotary Encoder:: direction: ");
if (direction == DIRECTION_CW)
Serial.print("CLOCKWISE");
else
Serial.print("ANTICLOCKWISE");
Serial.print(" - count: ");
Serial.println(counter);
prev_counter = counter;
}
if (button.isPressed()) {
Serial.println("The button is pressed");
}
// TO DO: your other work here
}
Nun, während Sie den Drehknopf drehen, werden Sie feststellen, dass Informationen im seriellen Monitor erscheinen, ähnlich dem, was Sie im vorherigen Code gesehen haben.
※ Notiz:
- Sie könnten auf Tutorials auf anderen Websites stoßen, die zwei Unterbrechungen für einen einzelnen Encoder verwenden, aber das ist unnötig und verschwenderisch. Nur eine Unterbrechung reicht aus.
- Es ist wichtig, das volatile-Schlüsselwort für globale Variablen zu verwenden, die in der Unterbrechung verwendet werden. Wenn man dies vernachlässigt, kann dies zu unerwarteten Problemen führen.
- Halte den Code innerhalb der Unterbrechung so einfach wie möglich. Vermeide es, Serial.print() oder Serial.println() innerhalb der Unterbrechung zu verwenden.
Arduino Nano ESP32 Drehencoder-Anwendung
Mit dem Drehencoder können wir die folgenden Anwendungen durchführen, aber nicht darauf beschränkt:
- Arduino Nano ESP32 - Drehencoder steuert die Position des Sevo-Motors
- Arduino Nano ESP32 - Drehencoder steuert die Helligkeit der LED
- Arduino Nano ESP32 - Drehencoder steuert die Geschwindigkeit des Schrittmotors
Video Tutorial
Wir erwägen die Erstellung von Video-Tutorials. Wenn Sie Video-Tutorials für wichtig halten, abonnieren Sie bitte unseren YouTube-Kanal , um uns zu motivieren, die Videos zu erstellen.