Arduino Mega - MOSFET-Modul

In diesem Tutorial lernen Sie, wie Sie mit dem Arduino Mega 2560 über ein MOSFET-Modul eine 12V-DC-Last schalten und dimmen. Der Pin des Mega liefert nur 5V und wenige Milliampere. Das Modul lässt dieses kleine Signal aber eine starke Last wie einen LED-Streifen, einen Lüfter oder eine Pumpe steuern. Im Detail lernen wir:

Wir empfehlen:

Arduino Mega und MOSFET-Modul AOD4184, LR7843 oder FR120N

Erforderliche Hardware

1×Arduino MEGA
1×Alternativ: DIYables MEGA Development Board
1×USB 2.0 Kabel Typ A/B (für USB-A PC)
1×USB 2.0 Kabel Typ C/B (für USB-C PC)
1×MOSFET Module (AOD4184, LR7843 or FR120N)
1×12V LED-Streifen
1×(Alternativ) 12V DC Kühlventilator
1×12V Netzteil
1×DC-Stromanschluss
1×Verbindungskabel
1×(Empfohlen) Screw Terminal Block Shield for Arduino Uno/Mega
1×(Empfohlen) Sensors/Servo Expansion Shield for Arduino Mega
1×(Empfohlen) Breadboard Shield for Arduino Mega
1×(Empfohlen) Enclosure for Arduino Mega

Oder Sie können die folgenden Kits kaufen:

1×DIYables Sensor-Kit (18 Sensoren/Displays)
Offenlegung: Einige der in diesem Abschnitt bereitgestellten Links sind Amazon-Affiliate-Links. Wir können eine Provision für Käufe erhalten, die über diese Links getätigt werden, ohne zusätzliche Kosten für Sie. Wir schätzen Ihre Unterstützung.

Über das MOSFET-Modul

Ein MOSFET-Modul ist ein elektronischer Schalter für Gleichstrom. Der Arduino Mega sendet ein Logiksignal an das Modul, und das Modul öffnet oder schließt den Strompfad der Last. Es hat keine beweglichen Teile, daher macht es kein Klickgeräusch, nutzt sich nicht ab und kann sehr schnell schalten. Weil es schnell ist, nimmt es ein PWM-Signal an. Der Arduino Mega kann also einen 12V-LED-Streifen nicht nur ein- und ausschalten, sondern auch seine Helligkeit oder die Drehzahl eines Lüfters oder Motors einstellen.

Dieses Tutorial behandelt drei Module: AOD4184 (auch als D4184 verkauft), LR7843 und FR120N. Sie haben dasselbe Platinendesign, dieselben Pins, dieselbe Verdrahtung und denselben Code. Der einzige Unterschied ist der MOSFET-Chip auf der Platine.

AOD4184 LR7843 FR120N
MOSFET AOD4184A (N-Kanal) IRLR7843 (N-Kanal) IRFR120N (N-Kanal)
Max. Lastspannung (MOSFET-Nennwert) 40V DC 30V DC 100V DC
Max. Strom (MOSFET-Nennwert) 50A 161A 9.4A
Durchlasswiderstand RDS(on) ca. 7 mΩ ca. 3.3 mΩ ca. 210 mΩ
Praktischer Strom ohne Kühlkörper ca. 10–15A ca. 15A ca. 2A
Steuersignal 3.3V / 5V Logik, aktiv HIGH 3.3V / 5V Logik, aktiv HIGH 3.3V / 5V Logik, aktiv HIGH
Isolation PC817-Optokoppler PC817-Optokoppler PC817-Optokoppler
PWM ja, höchstens ca. 1 kHz ja, höchstens ca. 1 kHz ja, höchstens ca. 1 kHz
Lasttyp nur DC nur DC nur DC

Die großen Stromwerte (50A und 161A) sind die Grenzwerte des Chips selbst. Die kleine Platine kann nicht so viel Strom tragen. In der Praxis ist die Wärme die Grenze, daher sollten Sie sich an der Zeile "ohne Kühlkörper" orientieren.

Die Pinbelegung des MOSFET-Moduls

Pinbelegung des MOSFET-Moduls AOD4184, LR7843 und FR120N

Das Modul hat zwei Seiten. Die Steuerseite ist eine 2-polige Stiftleiste (2.54mm Raster) für den Arduino Mega. Die Leistungsseite besteht aus drei Schraubklemmen für die Last und ihre Stromversorgung.

Steuerseite:

  • PWM-Pin: muss mit einem Ausgangspin des Arduino Mega verbunden werden. Dieser Pin empfängt das EIN/AUS- oder PWM-Signal.
  • GND-Pin: muss mit GND des Arduino Mega verbunden werden. Das ist die Signalmasse.

Leistungsseite:

  • +-Pin: muss mit dem Pluskabel der Stromversorgung der Last (zum Beispiel 12V) und mit dem Pluskabel der Last verbunden werden. Beide Kabel teilen sich diese eine Klemme.
  • LOAD-Pin: muss mit dem Minuskabel der Last verbunden werden. Das ist die Seite, die der MOSFET schaltet.
  • −-Pin: muss mit dem Minuskabel (Masse) der Stromversorgung der Last verbunden werden

※ Notiz:

Die Anordnung der Pins kann sich von Hersteller zu Hersteller unterscheiden, und die Beschriftungen können sich von Charge zu Charge leicht ändern. Orientieren Sie sich beim Verwenden des Moduls immer an den Beschriftungen auf dem Modul. Schauen Sie genau hin!

Wie das MOSFET-Modul funktioniert

Das Modul besteht aus zwei Hauptteilen:

  • Ein PC817-Optokoppler auf der Eingangsseite. Der PWM-Pin speist einen kleinen Widerstand und eine winzige LED im Inneren. Das Licht dieser LED schaltet einen Fototransistor ein, der ebenfalls im PC817 sitzt, und der Fototransistor steuert das Gate des MOSFET. Weil das Signal als Licht übertragen wird, sind die Seite des Arduino Mega und die Seite der Last elektrisch getrennt. Die Signalmasse (GND) und die Masse der Last sind auf dem Modul NICHT verbunden.
  • Ein N-Kanal-MOSFET, der als Low-Side-Schalter verwendet wird. Er sitzt zwischen der LOAD-Klemme und der −-Klemme und schaltet daher das Minuskabel der Last. Ein Widerstand am Gate zieht das Gate auf 0V, wenn der Optokoppler ausgeschaltet ist.

Die Gate-Spannung kommt über einen Spannungsteiler aus der Versorgung der Last (etwa die Hälfte der Versorgungsspannung). Deshalb muss die Versorgung der Last mindestens etwa 6V haben. Wenn die Last mehr als einige Ampere zieht, verwenden Sie 9V oder mehr. Das Modul funktioniert mit einer 5V-Versorgung der Last NICHT gut.

Das Modul ist aktiv HIGH. Die drei Fälle unten zeigen, was bei jedem Signal passiert, das der Arduino Mega an den PWM-Pin senden kann.

Fall 1: Der PWM-Pin ist HIGH (5V)

  • Das 5V-Signal schickt einige mA durch die LED des Optokopplers, und die LED leuchtet im Chip. Jeder Pin des Arduino Mega kann diesen kleinen Strom direkt liefern.
  • Der Fototransistor leitet, und das MOSFET-Gate steigt auf etwa die Hälfte der Versorgungsspannung der Last (etwa 6V bei einem 12V-Netzteil).
  • Der MOSFET ist voll EIN. Er wirkt wie ein geschlossener Schalter mit sehr kleinem Widerstand: einige mΩ beim AOD4184 und LR7843, etwa 0.2Ω beim FR120N.
  • Der Strom fließt nun in einer Schleife: Netzteil + → +-Klemme → Last → LOAD-Klemme → MOSFET → −-Klemme → Netzteil −.
  • Fast die gesamte Versorgungsspannung (etwa 12V) erreicht die Last, sie läuft also mit voller Leistung.
  • Im Code: digitalWrite(MOSFET_PIN, HIGH) oder analogWrite(MOSFET_PIN, 255).

Fall 2: Der PWM-Pin ist LOW (0V)

  • Der Pin liefert 0V, daher fließt kein Strom durch die LED des Optokopplers, und sie bleibt dunkel.
  • Der Fototransistor ist aus. Der Gate-Widerstand hält das MOSFET-Gate auf 0V.
  • Der MOSFET ist AUS und wirkt wie ein offener Schalter zwischen LOAD und −.
  • Das −-Kabel der Last hat keinen Weg zur Masse, daher fließt kein Strom. Die Last sieht 0V und ist AUS.
  • Im Code: digitalWrite(MOSFET_PIN, LOW) oder analogWrite(MOSFET_PIN, 0).

Fall 3: Der PWM-Pin erhält ein PWM-Signal

  • AnalogWrite() lässt den Pin etwa 500- bis 1000-mal pro Sekunde zwischen LOW und HIGH wechseln.
  • Während jedes HIGH-Teils ist das Modul in Fall 1 (Last EIN). Während jedes LOW-Teils ist es in Fall 2 (Last AUS). Die Last erhält also 12V-Impulse.
  • Das Tastverhältnis ist der Anteil jeder Periode, in dem der Pin HIGH bleibt. Es wird durch den Wert von analogWrite() festgelegt: Tastverhältnis = Wert / 255. Die mittlere Spannung und die mittlere Leistung der Last entsprechen dem Tastverhältnis multipliziert mit dem vollen Wert.
Tastverhältnis analogWrite()-Wert Mittlere Spannung bei 12V-Versorgung Ergebnis
20% 51 ca. 2.4V sehr dunkler LED-Streifen, sehr langsamer Motor
40% 102 ca. 4.8V weniger als halbe Leistung
60% 153 ca. 7.2V mehr als halbe Leistung
80% 204 ca. 9.6V fast volle Leistung
  • Ein LED-Streifen sieht dunkler aus, weil er schneller flackert, als das Auge folgen kann. Ein Motor, Lüfter oder eine Pumpe dreht langsamer, weil die drehende Masse die Impulse glättet.
  • Die PWM-Frequenz muss niedrig bleiben (etwa 500 Hz bis 1 kHz). Bei einer höheren Frequenz kann der langsame PC817 den MOSFET nicht mehr voll schalten, die Impulse verlieren ihre Form, und der MOSFET wird heiß. Siehe den Hinweis zur Frequenz im Programmierteil unten.
  • Der Beispielcode in diesem Tutorial durchläuft das Tastverhältnis von 10% bis 100%.

Schaltplan

Der Arduino Mega sendet sein Signal von Pin 2 an den PWM-Pin des Moduls, während der 12V-LED-Streifen seinen Strom vom 12V-Netzteil über die Schraubklemmen des Moduls erhält.

Schaltplan Arduino Mega mit MOSFET-Modul AOD4184, LR7843 oder FR120N

Dieses Bild wurde mit Fritzing erstellt. Klicken Sie, um das Bild zu vergrößern.

Von Nach
Arduino Mega Pin 2 PWM-Pin des Moduls
Arduino Mega GND GND-Pin des Moduls
12V-Netzteil + (über DC-Buchse) +-Klemme des Moduls
12V-Netzteil − (über DC-Buchse) −-Klemme des Moduls
LED-Streifen + +-Klemme des Moduls (gemeinsam mit Netzteil +)
LED-Streifen − LOAD-Klemme des Moduls

WARNING

Schließen Sie die 12V-Versorgung niemals an einen Pin des Arduino Mega an. Die 12V gehen nur an die Schraubklemmen des MOSFET-Moduls.

Der Arduino Mega hat 15 PWM-Pins (Pins 2 bis 13 und 44 bis 46). Sie können also einen anderen PWM-Pin wählen, wenn Pin 2 schon belegt ist. Ändern Sie dazu einfach die Pin-Nummer im Code. Für den Helligkeitsteil wird ein PWM-Pin benötigt; für einfaches EIN/AUS funktioniert jeder digitale Pin.

Das MOSFET-Modul mit anderen 12V-Geräten verdrahten

Die Seite des Arduino Mega bleibt für alle Geräte unten gleich: Pin 2 an den PWM-Pin, GND an den GND-Pin. Nur die Leistungsseite ändert sich. In allen Fällen geht das Netzteil + an +, das Netzteil − geht an −, das +-Kabel des Geräts geht ebenfalls an +, und das −-Kabel des Geräts geht an LOAD.

Prüfen Sie vor der Wahl eines Geräts zwei Dinge:

  • Die Spannung des Netzteils muss zum Gerät passen. Ein 12V-Gerät braucht ein 12V-Netzteil. Sie muss außerdem 6V oder mehr betragen, sonst schaltet das Modul nicht gut.
  • Das Modul muss zum Strom des Geräts passen. Der FR120N ist nur für kleine Geräte geeignet (etwa 2A ohne Kühlkörper). Für größere Ströme verwenden Sie den AOD4184 oder den LR7843.

Zur Freilaufdiode: Ein Motor, ein Lüfter, eine Pumpe und ein Magnetventil haben alle eine Spule im Inneren. Wenn der MOSFET abschaltet, erzeugt die Spule eine Spannungsspitze, die den MOSFET beschädigen kann. Das Modul hat keine Diode auf der Platine, daher müssen Sie eine hinzufügen (1N5819 oder 1N4007), und zwar über die Kabel des Geräts. Die Kathode (die Seite mit dem Streifen) geht an das +-Kabel des Geräts, und die Anode geht an das −-Kabel des Geräts. In den Tabellen unten steht nur "Freilaufdiode: erforderlich", wenn Sie sie brauchen.

Der Code in diesem Tutorial funktioniert für jedes Gerät hier ohne Änderung. Die einzige Ausnahme sind die Magnetspulen: Verwenden Sie dafür nur HIGH oder LOW (100% oder 0%) und nicht den Fade-Teil.

Beispiel 1: 12V-LED-Streifen (einfarbig)

Schaltplan MOSFET-Modul mit 12V-LED-Streifen

Dieses Bild wurde mit Fritzing erstellt. Klicken Sie, um das Bild zu vergrößern.

Element Detail
Pluskabel des Streifens (oft mit 12V markiert) +-Klemme des Moduls
Minuskabel des Streifens LOAD-Klemme des Moduls
Freilaufdiode nicht nötig (keine Spule)
PWM-Wirkung Helligkeit

Ein längerer Streifen zieht mehr Strom. Lesen Sie daher den Strom Ihres Streifens, bevor Sie ein Modul auswählen. Diese Verdrahtung gilt nur für einen einfarbigen Streifen. RGB- und adressierbare Streifen werden anders verdrahtet.

Beispiel 2: 12V-Gleichstrommotor

Schaltplan MOSFET-Modul mit einem 12V-Gleichstrommotor

Dieses Bild wurde mit Fritzing erstellt. Klicken Sie, um das Bild zu vergrößern.

Element Detail
Pluskabel des Motors +-Klemme des Moduls
Minuskabel des Motors LOAD-Klemme des Moduls
Freilaufdiode erforderlich
PWM-Wirkung Drehzahl

Der Motor dreht sich nur in eine Richtung. Wenn Sie die Richtung ändern müssen, verwenden Sie stattdessen einen Motortreiber wie den L298N. Siehe das Tutorial Arduino Mega - Gleichstrommotor.

Beispiel 3: 12V-Lüfter

12V-Lüfter an ein MOSFET-Modul angeschlossen

Dieses Bild wurde mit Fritzing erstellt. Klicken Sie, um das Bild zu vergrößern.

Element Detail
Rotes Kabel (+) +-Klemme des Moduls
Schwarzes Kabel (−) LOAD-Klemme des Moduls
Gelbes Kabel (Drehzahlsignal, falls vorhanden) nicht verbunden
Freilaufdiode erforderlich (billig und harmlos)
PWM-Wirkung Drehzahl

Einige Lüfter laufen bei einem sehr niedrigen Tastverhältnis nicht an. Beginnen Sie über etwa 30%.

Beispiel 4: 12V-Wasserpumpe

Schaltplan MOSFET-Modul mit 12V-Wasserpumpe

Dieses Bild wurde mit Fritzing erstellt. Klicken Sie, um das Bild zu vergrößern.

Element Detail
Pluskabel der Pumpe +-Klemme des Moduls
Minuskabel der Pumpe LOAD-Klemme des Moduls
Freilaufdiode erforderlich
PWM-Wirkung Fördermenge

Lassen Sie die Pumpe niemals trocken laufen. Halten Sie ihren Einlass unter Wasser.

Beispiel 5: 12V-Magnetventil (stromlos geschlossen)

Schaltplan eines 12V-Magnetventils mit einem MOSFET-Modul

Dieses Bild wurde mit Fritzing erstellt. Klicken Sie, um das Bild zu vergrößern.

Element Detail
Pluskabel des Ventils +-Klemme des Moduls
Minuskabel des Ventils LOAD-Klemme des Moduls
Freilaufdiode erforderlich
Steuerung EIN = Ventil offen, AUS = Ventil geschlossen

Ein Ventil hat nur zwei Zustände, daher reicht die EIN/AUS-Steuerung. Verwenden Sie kein PWM.

Beispiel 6: 12V-Magnetschloss

Verdrahtung von MOSFET-Modul und 12V-Magnetschloss

Dieses Bild wurde mit Fritzing erstellt. Klicken Sie, um das Bild zu vergrößern.

Element Detail
Pluskabel des Schlosses +-Klemme des Moduls
Minuskabel des Schlosses LOAD-Klemme des Moduls
Freilaufdiode erforderlich
Steuerung nur ganz EIN oder ganz AUS, kein PWM

Die Spule des Schlosses wird heiß, wenn sie lange EIN bleibt. Schalten Sie sie nur für einen kurzen Impuls EIN, um die Tür zu entriegeln, und dann wieder AUS. Ein vollständiges Schlossprojekt finden Sie im Tutorial Arduino Mega - Magnetschloss.

Wie man den Arduino Mega für das MOSFET-Modul programmiert

Es wird keine Bibliothek benötigt. Der Code verwendet nur die eingebauten Arduino-Funktionen.

  • Der erste Schritt ist, den Pin des Arduino Mega anzugeben, der mit dem PWM-Pin des Moduls verbunden ist:
const int MOSFET_PIN = 2;
  • Der Pin muss in der Funktion setup() als Ausgang festgelegt werden:
pinMode(MOSFET_PIN, OUTPUT);
  • Um die Last ganz EIN oder ganz AUS zu schalten, kann der Pin auf HIGH oder LOW geschrieben werden:
digitalWrite(MOSFET_PIN, HIGH); // load ON digitalWrite(MOSFET_PIN, LOW); // load OFF
  • Um die Leistung der Last einzustellen, wird mit analogWrite() ein PWM-Wert von 0 bis 255 geschrieben. Der Code wandelt eine Prozentzahl mit map() in diesen Bereich um:
int duty = map(percent, 0, 100, 0, 255); analogWrite(MOSFET_PIN, duty);

Die Standard-PWM-Frequenz von analogWrite() beim Arduino Mega beträgt etwa 490 Hz (etwa 980 Hz an den Pins 4 und 13). Beide Werte liegen im sicheren Bereich des Moduls. Behalten Sie also den Standard bei und erhöhen Sie die PWM-Frequenz nicht.

Arduino Mega 2560 Code für das MOSFET-Modul

Der folgende Code führt diese Schritte immer wieder aus:

  • Schaltet die Last 2 Sekunden lang ganz EIN, dann 2 Sekunden lang ganz AUS
  • Erhöht die Leistung in Schritten von 10% von 10% auf 100%, ein Schritt alle 0.5 Sekunden
  • Senkt die Leistung von 90% zurück auf 0% und wartet dann 1 Sekunde
/* * Dieser Arduino Mega Code wurde von newbiely.de entwickelt * Dieser Arduino Mega Code wird der Öffentlichkeit ohne jegliche Einschränkung zur Verfügung gestellt. * Für vollständige Anleitungen und Schaltpläne besuchen Sie bitte: * https://newbiely.de/tutorials/arduino-mega/arduino-mega-mosfet-module */ const int MOSFET_PIN = 2; // Arduino Mega pin connected to the PWM pin of the MOSFET module void setup() { Serial.begin(9600); pinMode(MOSFET_PIN, OUTPUT); analogWrite(MOSFET_PIN, 0); // start with the load OFF } void setLoad(int percent) { int duty = map(percent, 0, 100, 0, 255); // convert 0-100% to 0-255 analogWrite(MOSFET_PIN, duty); Serial.print("Load power: "); Serial.print(percent); Serial.println("%"); } void loop() { // turn the load fully ON, then fully OFF Serial.println("Load: ON"); setLoad(100); delay(2000); Serial.println("Load: OFF"); setLoad(0); delay(2000); // increase the power step by step (PWM) for (int percent = 10; percent <= 100; percent += 10) { setLoad(percent); delay(500); } // decrease the power step by step (PWM) for (int percent = 90; percent >= 0; percent -= 10) { setLoad(percent); delay(500); } delay(1000); }

Schnelle Schritte

  • Wenn Sie den Arduino Mega 2560 zum ersten Mal verwenden, lesen Sie wie man die Umgebung für den Arduino Mega in der Arduino IDE einrichtet.
  • Verdrahten Sie die Bauteile wie im Diagramm gezeigt. Lassen Sie das 12V-Netzteil vorerst ausgesteckt.
  • Verbinden Sie das Arduino-Mega-Board über ein USB-Kabel mit Ihrem Computer.
  • Öffnen Sie die Arduino IDE auf Ihrem Computer.
  • Wählen Sie das Board Arduino Mega or Mega 2560 und den richtigen COM-Port aus.
  • Kopieren Sie den obigen Code und fügen Sie ihn in die Arduino IDE ein.
  • Klicken Sie auf die Schaltfläche Upload, um den Code auf den Arduino Mega hochzuladen.
  • Stecken Sie das 12V-Netzteil ein.
  • Öffnen Sie den Serial Monitor und stellen Sie die Baudrate auf 9600 ein.
  • Beobachten Sie den LED-Streifen: Er leuchtet 2 Sekunden lang mit voller Helligkeit, ist 2 Sekunden lang aus, wird dann langsam heller und danach langsam dunkler.
  • Sehen Sie das Ergebnis im Serial Monitor:
∞
Newbiely | Arduino IDE 2.3.8
──
☐
✕
File
Edit
Sketch
Tools
Help
Arduino Mega Or...
Newbiely.ino
···
8 Serial.println("Hello World!");
Output
Serial Monitor
Message (Enter to send message to 'Arduino Mega Or...' on 'COM15')
New Line
9600 baud
Load: ON Load power: 100% Load: OFF Load power: 0% Load power: 10% Load power: 20% Load power: 30% Load power: 40% Load power: 50% Load power: 60% Load power: 70% Load power: 80% Load power: 90% Load power: 100% Load power: 90% Load power: 80% Load power: 70% Load power: 60% Load power: 50% Load power: 40% Load power: 30% Load power: 20% Load power: 10% Load power: 0%
Ln 11, Col 1
Arduino Mega Or... on COM15
2

Wenn Sie statt des LED-Streifens einen 12V-Lüfter verwenden, dreht der Lüfter mit voller Drehzahl, bleibt stehen und wird dann im gleichen Muster schneller und langsamer.

Zusätzliches Wissen

AOD4184 vs. LR7843 vs. FR120N: Welches wählen

AOD4184 LR7843 FR120N
Max. Lastspannung 40V 30V 100V
Durchlasswiderstand ca. 7 mΩ ca. 3.3 mΩ ca. 210 mΩ
Praktischer Strom (ohne Kühlkörper) ca. 10–15A ca. 15A ca. 2A
Geeignet für 12V- / 24V- / 36V-Lasten 12V- / 24V-Lasten mit hohem Strom kleine 24V- / 48V-Lasten
  • LR7843: Er hat den niedrigsten Widerstand und bleibt daher bei hohem Strom am kühlsten. Er ist die beste Wahl für starke 12V- oder 24V-Lasten, wie einen langen LED-Streifen mit hoher Leistung oder einen großen Motor. Seine Grenze ist 30V.
  • AOD4184: ein guter Allrounder. Er verträgt bis zu 40V und einen starken Strom.
  • FR120N: Er verträgt die höchste Spannung (bis zu 100V), hat aber den höchsten Widerstand, daher ist er nur für kleine Ströme von etwa 2A ohne Kühlkörper geeignet.

Es ist offensichtlich, dass der LR7843 die beste Wahl für hohen Strom ist, der FR120N die beste Wahl für hohe Spannung, und der AOD4184 liegt in der Mitte. Welchen Sie auch verwenden: Berühren Sie den MOSFET nach einigen Minuten Betrieb. Wenn er zu heiß zum Anfassen ist, fügen Sie einen Kühlkörper hinzu oder verringern Sie die Last.

MOSFET-Modul vs. Relais

MOSFET-Modul Relais
Lasttyp nur DC AC oder DC
Geräusch lautlos klickt
Bewegliche Teile keine ja
Schaltgeschwindigkeit sehr schnell langsam
PWM (Dimmen, Drehzahlregelung) ja nein
Lebensdauer lang begrenzt durch Kontaktverschleiß

Wählen Sie das MOSFET-Modul für DC-Lasten, besonders wenn Sie Helligkeit oder Drehzahl steuern wollen. Wählen Sie das Relais, wenn das Gerät mit Netzspannung (AC) läuft.

Video Tutorial

Wir erwägen die Erstellung von Video-Tutorials. Wenn Sie Video-Tutorials für wichtig halten, abonnieren Sie bitte unseren YouTube-Kanal , um uns zu motivieren, die Videos zu erstellen.

※ UNSERE NACHRICHTEN

  • Sie können gerne den Link zu diesem Tutorial teilen. Bitte verwenden Sie jedoch unsere Inhalte nicht auf anderen Websites. Wir haben viel Mühe und Zeit in die Erstellung der Inhalte investiert, bitte respektieren Sie unsere Arbeit!