Arduino Nano - DotStar-LED-Streifen
In diesem Tutorial lernen wir, wie man den Arduino Nano verwendet, um DotStar RGB-LED-Streifen zu steuern. Im Detail werden wir lernen:
- Wie man Arduino Nano mit dem DotStar-LED-Streifen verbindet
- Wie man den Arduino Nano programmiert, um die Farbe und Helligkeit jedes einzelnen LEDs auf dem DotStar-LED-Streifen zu steuern
- Wie man den Arduino Nano programmiert, um den Kometeneffekt für den DotStar-LED-Streifen zu erzeugen
Erforderliche Hardware
Oder Sie können die folgenden Kits kaufen:
| 1 | × | DIYables Sensor-Kit (30 Sensoren/Displays) | |
| 1 | × | DIYables Sensor-Kit (18 Sensoren/Displays) |
Offenlegung: Einige der in diesem Abschnitt bereitgestellten Links sind Amazon-Affiliate-Links. Wir können eine Provision für Käufe erhalten, die über diese Links getätigt werden, ohne zusätzliche Kosten für Sie. Wir schätzen Ihre Unterstützung.
Über DotStar RGB-LED-Streifen
Pinbelegung
Der DotStar RGB-LED-Streifen hat drei Pins:
- GND-Pin: muss mit GND (0 V) verbunden werden.
- CI-Pin: Taktpin, der das Taktsignal empfängt. Es sollte mit einem Pin des Arduino Nano verbunden werden.
- DI-Pin: Datenpin, der das Steuersignal empfängt. Es sollte mit einem Pin des Arduino Nano verbunden werden.
- 5V-Pin: muss mit der externen Stromversorgung (5 V) verbunden werden.
Verdrahtungsdiagramm
Dieses Bild wurde mit Fritzing erstellt. Klicken Sie, um das Bild zu vergrößern.
Siehe Der beste Weg, den Arduino Nano und andere Komponenten mit Strom zu versorgen.
Wie programmiert man DotStar RGB-LED-Streifen
- Eine DotStar-Bibliothek einbinden
#include <Adafruit_DotStar.h>
#include <SPI.h> // DIESEN ZEILE FÜR GEMMA ODER TRINKET AUSKOMMENTIEREN
- Deklariere ein DotStar-Objekt
#define NUMPIXELS 144 // Anzahl der LEDs im Streifen
// So steuern Sie die LEDs von zwei beliebigen Pins aus:
#define DATAPIN D5 // Der Arduino Nano Pin
#define CLOCKPIN D6 // Der Arduino Nano Pin
Adafruit_DotStar strip(NUMPIXELS, DATAPIN, CLOCKPIN, DOTSTAR_BRG);
- Initialisiert den DotStar
strip.begin(); // Pins als Ausgang initialisieren
strip.setBrightness(255);
strip.show(); // Alle LEDs so schnell wie möglich ausschalten
- Setze die Farbe (r, g, b) jeder einzelnen LED (Pixel genannt).
strip.setPixelColor(pixel, g, r, b);
- Stellen Sie die Helligkeit aller Streifen ein.
strip.setBrightness(100); // ein Wert von 0 bis 255
※ Notiz:
- DotStar.setBrightness() wird für alle Pixel auf dem LED-Streifen verwendet. Um die Helligkeit für jedes einzelne Pixel festzulegen, können wir den Farbwert skalieren.
- Die durch DotStar.setBrightness() und DotStar.setPixelColor() festgelegten Werte wirken erst, wenn DotStar.show() aufgerufen wird.
Arduino Nano Code
Der folgende Code färbt Pixel nacheinander rot, mit einer Verzögerung zwischen jedem Pixel.
/*
* Dieser Arduino Nano Code wurde von newbiely.de entwickelt
* Dieser Arduino Nano Code wird der Öffentlichkeit ohne jegliche Einschränkung zur Verfügung gestellt.
* Für vollständige Anleitungen und Schaltpläne besuchen Sie bitte:
* https://newbiely.de/tutorials/arduino-nano/arduino-nano-dotstar-led-strip
*/
#include <Adafruit_DotStar.h>
#include <SPI.h> // COMMENT OUT THIS LINE FOR GEMMA OR TRINKET
#define NUMPIXELS 144 // Number of LEDs in strip
// Here's how to control the LEDs from any two pins:
#define DATAPIN D5 // The Arduino Nano pin
#define CLOCKPIN D6 // The Arduino Nano pin
Adafruit_DotStar strip(NUMPIXELS, DATAPIN, CLOCKPIN, DOTSTAR_BRG);
void setup() {
Serial.begin(9600);
strip.begin(); // INITIALIZE NeoPixel strip object (REQUIRED)
strip.show(); // Turn OFF all pixels ASAP
strip.setBrightness(255);
}
void loop() {
for (int pixel = 0; pixel < NUMPIXELS; pixel++) {
// red color
int r = 255; // CHANGE COLOR AS YOUR DESIRE
int g = 0; // CHANGE COLOR AS YOUR DESIRE
int b = 0; // CHANGE COLOR AS YOUR DESIRE
strip.clear(); // turn off all pixel
strip.setPixelColor(pixel, g, r, b); // turn on a single pixel
strip.show();
delay(1000); // keep each pixel on 1 seconds
}
}
Schnelle Schritte
- Verbinden Sie die Komponenten gemäß dem bereitgestellten Diagramm.
- Schließen Sie das Arduino Nano-Board über ein USB-Kabel an Ihren Computer an.
- Starten Sie die Arduino IDE auf Ihrem Computer.
- Wählen Sie das Arduino Nano-Board und den entsprechenden COM-Port aus.
- Öffnen Sie den Library Manager, indem Sie auf das Library Manager-Symbol in der linken Navigationsleiste der Arduino IDE klicken.
- Suchen Sie „Adafruit DotStar“, und finden Sie dann die DotStar-Bibliothek von Adafruit.
- Klicken Sie auf die Install-Schaltfläche, um die DotStar-Bibliothek zu installieren.
- Ihnen wird aufgefordert, die Abhängigkeit zu installieren. Klicken Sie auf die Schaltfläche Alle installieren.
- Kopieren Sie den obigen Code und öffnen Sie ihn mit der Arduino IDE.
- Klicken Sie in der Arduino IDE auf die Upload-Schaltfläche, um den Code auf das Arduino Nano hochzuladen.
- Sehen Sie den LED-Effekt.
Arduino Nano Code - LED-Streifen-Kometeneffekt
Der untenstehende Code erzeugt den Kometen-Effekt für den DotStar-LED-Streifen.
/*
* Dieser Arduino Nano Code wurde von newbiely.de entwickelt
* Dieser Arduino Nano Code wird der Öffentlichkeit ohne jegliche Einschränkung zur Verfügung gestellt.
* Für vollständige Anleitungen und Schaltpläne besuchen Sie bitte:
* https://newbiely.de/tutorials/arduino-nano/arduino-nano-dotstar-led-strip
*/
#include <Adafruit_DotStar.h>
#include <SPI.h> // COMMENT OUT THIS LINE FOR GEMMA OR TRINKET
#define COMET_LENGTH_ALL 30 // in pixel COMET_LENGTH_ALL = COMET_LENGTH_BODY + COMET_LENGTH_HEAD
#define COMET_LENGTH_BODY 25 // in pixel
#define COMET_LENGTH_HEAD 5 // in pixel
#define TWO_COMET_DISTANCE 10 // in pixel
#define COMET_SPEED 2000 // in millisecond, the time need to move through 144 pixels
#define COMET_COLOR_R 204 // color
#define COMET_COLOR_G 255 // color
#define COMET_COLOR_B 255 // color
#define COMET_BRIGHTNESS_MIN 1
#define COMET_BRIGHTNESS_MAX 200
#define COMET_BRIGHTNESS_HEAD 80
#define FLICKER_MAX 255
#define FLICKER_MIN 100
#define FLICKER_SPEED 800 // in millisecond
#define NUMPIXELS 144 // Number of LEDs in strip
// Here's how to control the LEDs from any two pins:
#define DATAPIN D5 // The Arduino Nano pin
#define CLOCKPIN D6 // The Arduino Nano pin
Adafruit_DotStar strip(NUMPIXELS, DATAPIN, CLOCKPIN, DOTSTAR_BRG);
int pos_head = 0;
unsigned long cometTimeStart;
unsigned long flickerTimeStart;
unsigned long progress;
unsigned long cometBrightness;
unsigned long flickerBrightness;
unsigned long TIME_PER_PIXEL;
void setup() {
Serial.begin(9600);
strip.begin(); // INITIALIZE NeoPixel strip object (REQUIRED)
strip.show(); // Turn OFF all pixels ASAP
strip.setBrightness(255);
TIME_PER_PIXEL = map(1, 0, NUMPIXELS, 0, COMET_SPEED);
cometTimeStart = millis();
flickerTimeStart = millis();
}
void loop() {
progress = millis() - flickerTimeStart;
if (progress >= 2 * FLICKER_SPEED) {
progress = 2 * FLICKER_SPEED;
flickerTimeStart = millis();
}
if (progress > FLICKER_SPEED)
progress = 2 * FLICKER_SPEED - progress;
flickerBrightness = map(progress, 0, FLICKER_SPEED, FLICKER_MIN, FLICKER_MAX);
strip.setBrightness(flickerBrightness);
progress = millis() - cometTimeStart;
if (progress >= TIME_PER_PIXEL) {
pos_head++;
pos_head %= (COMET_LENGTH_ALL + TWO_COMET_DISTANCE);
int offset = COMET_LENGTH_ALL - pos_head;
for (int pixel = 0; pixel < NUMPIXELS; pixel++) {
int pos_offset = pixel + offset;
pos_offset %= (COMET_LENGTH_ALL + TWO_COMET_DISTANCE);
if (pos_offset < COMET_LENGTH_BODY)
cometBrightness = map(pos_offset, 0, COMET_LENGTH_BODY - 1, COMET_BRIGHTNESS_MIN, COMET_BRIGHTNESS_MAX);
else if (pos_offset >= COMET_LENGTH_BODY && pos_offset < COMET_LENGTH_ALL)
cometBrightness = map(pos_offset - COMET_LENGTH_BODY + 1, 0, COMET_LENGTH_ALL - COMET_LENGTH_BODY, COMET_BRIGHTNESS_MAX, COMET_BRIGHTNESS_HEAD);
else
cometBrightness = 0;
int r = (COMET_COLOR_R * cometBrightness) >> 8;
int g = (COMET_COLOR_G * cometBrightness) >> 8;
int b = (COMET_COLOR_B * cometBrightness) >> 8;
strip.setPixelColor(pixel, g, r, b);
}
strip.show();
cometTimeStart = millis(); // new circle
}
}
※ Notiz:
Für alle anderen LED-Effekte bieten wir den kostenpflichtigen Programmierdienst an.
Video Tutorial
Wir erwägen die Erstellung von Video-Tutorials. Wenn Sie Video-Tutorials für wichtig halten, abonnieren Sie bitte unseren YouTube-Kanal , um uns zu motivieren, die Videos zu erstellen.