Arduino - Steuert das Türschloss über das Web
In diesem Tutorial lernen wir, wie man Arduino verwendet, um ein Türschloss über eine Weboberfläche zu steuern, die über einen Webbrowser auf einem Computer oder Smartphone zugänglich ist. So funktioniert das Ganze:
- Wir werden Arduino so programmieren, dass es als Webserver fungiert
- Wenn Sie die IP-Adresse Ihres Arduino in den Webbrowser eingeben, sendet der Webbrowser eine HTTP-Anfrage an den Arduino.
- Arduino sendet dem Webbrowser eine Webseite zurück. Die Webseite wird Folgendes anzeigen:
- Ob die Tür derzeit verschlossen oder entriegelt ist.
- Eine Taste zum Entriegeln der Tür.
- Eine weitere Taste zum Verriegeln der Tür.
- Falls dies das erste Mal ist, dass Sie Arduino Uno R4 verwenden, sehen Sie sich wie man die Umgebung für Arduino Uno R4 in der Arduino IDE einrichtet an.
- Öffnen Sie den Bibliotheks-Manager, indem Sie auf das Symbol Bibliotheksverwaltung auf der linken Seite der Arduino IDE klicken.
- Suchen Sie nach Webserver für Arduino Uno R4 WiFi und finden Sie die von DIYables erstellte Webserver-Bibliothek.
- Klicken Sie auf die Installieren-Schaltfläche, um die Webserver-Bibliothek hinzuzufügen.
- Kopiere den obigen Code und öffne ihn mit der Arduino IDE.
- Passe die WLAN-Informationen (SSID und Passwort) im Code an dein eigenes Netzwerk an.
- Klicke auf die Hochladen-Schaltfläche im Arduino IDE, um den Code auf den Arduino hochzuladen.
- Öffne den Seriellen Monitor.
- Schau dir das Ergebnis im Seriellen Monitor an.
- Sie sehen eine IP-Adresse, zum Beispiel: 192.168.0.2. Dies ist die IP-Adresse des Arduino-Webservers.
- Öffnen Sie einen Webbrowser und geben Sie eines der drei untenstehenden Formate in die Adressleiste ein:
- Bitte beachten Sie, dass die IP-Adresse abweichen kann. Vergewissern Sie sich, dass Sie den aktuellen Wert im Serial Monitor überprüfen.
- Zusätzlich sehen Sie im Serial Monitor die folgende Ausgabe.
- Überprüfen Sie den Zustand des Türschlosses.
- Sie sehen die Webseite des Arduino-Boards im Webbrowser wie unten dargestellt:
Erforderliche Hardware
Oder Sie können die folgenden Kits kaufen:
| 1 | × | DIYables STEM V4 IoT Starter-Kit (Arduino enthalten) | |
| 1 | × | DIYables Sensor-Kit (18 Sensoren/Displays) |
Offenlegung: Einige der in diesem Abschnitt bereitgestellten Links sind Amazon-Affiliate-Links. Wir können eine Provision für Käufe erhalten, die über diese Links getätigt werden, ohne zusätzliche Kosten für Sie. Wir schätzen Ihre Unterstützung.
Über Solenoid-Schloss und Arduino Uno R4
Wenn Sie mit dem Arduino Uno R4 und dem elektromagnetischen Türschloss nicht vertraut sind (wie deren Pinbelegung, wie sie funktionieren und wie man sie programmiert), können Sie in den folgenden Tutorials alles darüber lernen:
Verdrahtungsdiagramm
Dieses Bild wurde mit Fritzing erstellt. Klicken Sie, um das Bild zu vergrößern.
Arduino-Code
/*
* Dieser Arduino Code wurde von newbiely.de entwickelt
* Dieser Arduino Code wird der Öffentlichkeit ohne jegliche Einschränkung zur Verfügung gestellt.
* Für vollständige Anleitungen und Schaltpläne besuchen Sie bitte:
* https://newbiely.de/tutorials/arduino/arduino-controls-door-lock-via-web
*/
#include <UnoR4WiFi_WebServer.h>
#define RELAY_PIN 7 // Arduino pin connected to the solenoid lock via relay
const char HTML_CONTENT[] PROGMEM = R"rawliteral(
<!DOCTYPE HTML>
<html>
<head>
<link rel="icon" href="data:,">
<title>Door Control</title>
</head>
<body>
<h1>Door Control System</h1>
<p>The door is <span style="color: red;">%DOOR_STATUS%</span></p>
<br>
<a href="/door/unlock">UNLOCK</a>
<br><br>
<a href="/door/lock">LOCK</a>
</body>
</html>
)rawliteral";
// WiFi credentials
const char WIFI_SSID[] = "YOUR_WIFI_SSID"; // change your network SSID (name)
const char WIFI_PASSWORD[] = "YOUR_WIFI_PASSWORD"; // change your network password
// Door state
int doorState = LOW;
// Create web server instance
UnoR4WiFi_WebServer server;
// Handler for the main door control page
void sendHTML(WiFiClient& client) {
String status = (doorState == LOW) ? "LOCKED" : "UNLOCKED";
String response = HTML_CONTENT;
response.replace("%DOOR_STATUS%", status);
server.sendResponse(client, response.c_str());
}
void handleDoor(WiFiClient& client, const String& method, const String& request, const QueryParams& params, const String& jsonData) {
sendHTML(client);
}
// Handler for unlock command
void handleUnlock(WiFiClient& client, const String& method, const String& request, const QueryParams& params, const String& jsonData) {
doorState = HIGH;
digitalWrite(RELAY_PIN, doorState);
Serial.println("Unlock the door");
sendHTML(client);
}
// Handler for lock command
void handleLock(WiFiClient& client, const String& method, const String& request, const QueryParams& params, const String& jsonData) {
doorState = LOW;
digitalWrite(RELAY_PIN, doorState);
Serial.println("Lock the door");
sendHTML(client);
}
void setup() {
Serial.begin(9600);
delay(1000);
// Initialize relay pin
pinMode(RELAY_PIN, OUTPUT);
digitalWrite(RELAY_PIN, doorState);
Serial.println("Arduino Uno R4 WiFi - Door Lock Web Control");
// Connect to WiFi
Serial.print("Connecting to ");
Serial.println(WIFI_SSID);
WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}
Serial.println(" connected!");
Serial.print("IP address: ");
Serial.println(WiFi.localIP());
// Configure routes
server.addRoute("/", handleDoor);
server.addRoute("/door/unlock", handleUnlock);
server.addRoute("/door/lock", handleLock);
// Start server
server.begin();
Serial.println("\n=== Web Server Ready! ===");
Serial.print("Visit: http://");
Serial.println(WiFi.localIP());
}
void loop() {
server.handleClient();
}
Schnelle Schritte
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno' on 'COM15')
New Line
9600 baud
Arduino Uno R4 WiFi - Door Lock Web Control
Connecting to YOUR_WIFI_SSID
connected!
IP address: 192.168.0.254
Starting web server on IP: 192.168.0.254
=== Web Server Ready! ===
Visit: http://192.168.0.254
192.168.0.2
192.168.0.2/door/unlock
192.168.0.2/door/lock
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno' on 'COM15')
New Line
9600 baud
Arduino Uno R4 WiFi - Door Lock Web Control
Connecting to YOUR_WIFI_SSID
connected!
IP address: 192.168.0.254
Starting web server on IP: 192.168.0.254
=== Web Server Ready! ===
Visit: http://192.168.0.254
Method: GET
Requested path: /
Client disconnected
Method: GET
Requested path: /door/unlock
Unlock the door
Client disconnected
Method: GET
Requested path: /door/lock
Lock the door
Client disconnected
Wenn Sie das Erscheinungsbild der Webseite durch eine beeindruckende grafische Benutzeroberfläche (UI) verbessern möchten, können Sie sich an das Arduino - Web Server Tutorial zur Inspiration und Anleitung wenden.