Arduino - Türschloss-System mit Passwort
In diesem Tutorial lernen wir, wie man ein Türschloss mit Passwort herstellt. Das Tutorial umfasst zwei Hauptteile:
- Arduino - Türschloss-System mit Passwort unter Verwendung eines Keypads, elektromagnetisches Schloss.
- Arduino - Türschloss-System mit Passwort unter Verwendung eines Keypads, elektromagnetisches Schloss und LCD-Anzeige.
LCD ist optional. Es macht das System ein wenig bequemer.
Wenn die Tür mit einem korrekten Passwort entsperrt wird, bleibt sie 20 Sekunden lang entsperrt und wird danach wieder automatisch verriegelt. Der Arduino-Code unterstützt mehrere Passwörter.
※ Notiz:
Wir haben auch weitere Tutorials zu Türschloss-Systemen:
Erforderliche Hardware
Oder Sie können die folgenden Kits kaufen:
| 1 | × | DIYables STEM V3 Starter-Kit (Arduino enthalten) | |
| 1 | × | DIYables Sensor-Kit (30 Sensoren/Displays) | |
| 1 | × | DIYables Sensor-Kit (18 Sensoren/Displays) |
Offenlegung: Einige der in diesem Abschnitt bereitgestellten Links sind Amazon-Affiliate-Links. Wir können eine Provision für Käufe erhalten, die über diese Links getätigt werden, ohne zusätzliche Kosten für Sie. Wir schätzen Ihre Unterstützung.
Über Tastaturfeld und elektromagnetisches Schloss und LCD
Wenn Sie nichts über elektromagnetische Türschlösser, Keypad und LCD (Pinbelegung, wie sie funktionieren, wie man sie programmiert …) wissen, lernen Sie in den folgenden Tutorials mehr darüber.
Wie ein Türschloss-System funktioniert
Gültige Passwörter sind im Arduino-Code vordefiniert.
Eine Zeichenkette wird verwendet, um das vom Benutzer eingegebene Passwort zu speichern, bezeichnet als input string. Auf dem Tastenfeld werden zwei Tasten (* und #) für spezielle Zwecke verwendet: Passwort löschen und Passwort beenden. Das System funktioniert wie folgt:
- Außer zwei speziellen Tasten wird beim Drücken einer anderen Taste diese an die Eingabezeichenfolge angehängt.
- Wenn * gedrückt wird, wird die Eingabezeichenfolge gelöscht. Sie können sie verwenden, um die Passworteingabe zu starten oder neu zu beginnen.
- Wenn # gedrückt wird:
- Die Eingabezeichenfolge wird mit den vordefinierten Passwörtern verglichen. Wenn sie mit einem der vordefinierten Passwörter übereinstimmt, wird die Tür entriegelt.
- Unabhängig davon, ob das Passwort korrekt ist oder nicht, wird die Eingabezeichenfolge für die nächste Eingabe gelöscht.
Verdrahtungsdiagramm
- Arduino - Türschloss-System mit Passwort über Keypad, elektromagnetisches Schloss
Dieses Bild wurde mit Fritzing erstellt. Klicken Sie, um das Bild zu vergrößern.
- Arduino - Türschloss-System mit Passwort über Tastatur (Keypad), elektromagnetischem Schloss und LCD
Dieses Bild wurde mit Fritzing erstellt. Klicken Sie, um das Bild zu vergrößern.
Arduino-Code - Türschloss-System mit Passwort über ein Keypad, elektromagnetisches Schloss
/*
* Dieser Arduino Code wurde von newbiely.de entwickelt
* Dieser Arduino Code wird der Öffentlichkeit ohne jegliche Einschränkung zur Verfügung gestellt.
* Für vollständige Anleitungen und Schaltpläne besuchen Sie bitte:
* https://newbiely.de/tutorials/arduino/arduino-door-lock-system-using-password
*/
#include <Keypad.h>
const int RELAY_PIN = A0; // the Arduino pin, which connects to the IN pin of relay
const int ROW_NUM = 4; //four rows
const int COLUMN_NUM = 4; //four columns
char keys[ROW_NUM][COLUMN_NUM] = {
{'1', '2', '3', 'A'},
{'4', '5', '6', 'B'},
{'7', '8', '9', 'C'},
{'*', '0', '#', 'D'}
};
byte pin_rows[ROW_NUM] = {9, 8, 7, 6}; //connect to the row pinouts of the keypad
byte pin_column[COLUMN_NUM] = {5, 4, 3, 2}; //connect to the column pinouts of the keypad
Keypad keypad = Keypad( makeKeymap(keys), pin_rows, pin_column, ROW_NUM, COLUMN_NUM );
const String password_1 = "1234ABC"; // change your password here
const String password_2 = "5642CD"; // change your password here
const String password_3 = "4545B"; // change your password here
String input_password;
void setup() {
Serial.begin(9600);
input_password.reserve(32); // maximum input characters is 32, change if needed
pinMode(RELAY_PIN, OUTPUT); // initialize pin as an output.
digitalWrite(RELAY_PIN, HIGH); // lock the door
}
void loop() {
char key = keypad.getKey();
if (key) {
Serial.println(key);
if (key == '*') {
input_password = ""; // reset the input password
} else if (key == '#') {
if (input_password == password_1 || input_password == password_2 || input_password == password_3) {
Serial.println("The password is correct, unlocking the door in 20 seconds");
digitalWrite(RELAY_PIN, LOW); // unlock the door for 20 seconds
delay(20000);
digitalWrite(RELAY_PIN, HIGH); // lock the door
} else {
Serial.println("The password is incorrect, try again");
}
input_password = ""; // reset the input password
} else {
input_password += key; // append new character to input password string
}
}
}
Schnelle Schritte
- Verbinden Sie das Arduino-Board über ein USB-Kabel mit dem PC.
- Öffnen Sie die Arduino-IDE und wählen Sie das richtige Board und den richtigen Port aus.
- Navigieren Sie zum Bibliotheken-Symbol in der linken Leiste der Arduino-IDE.
- Suchen Sie nach „keypad“, und finden Sie dann die keypad-Bibliothek von Mark Stanley, Alexander Brevig.
- Klicken Sie auf die Schaltfläche Installieren, um die keypad-Bibliothek zu installieren.
- Kopiere den obigen Code und öffne ihn mit der Arduino IDE
- Klicke auf den Upload-Button in der Arduino IDE, um den Code auf den Arduino hochzuladen
- Lege die Armatureplatte nahe am Elektromagneten
- Öffne den Serial Monitor
- Drücke die Tasten 123456 und drücke #
- Drücke die Tasten 1234ABC und drücke #
- Beobachte die Anziehung zwischen Armatureplatte und Elektromagneten über 20 Sekunden
- Sieh dir das Ergebnis im Serial Monitor an
COM6
The password is incorrect, try again
The password is correct, unlocking the door in 20 seconds
Autoscroll
Clear output
9600 baud
Newline
Arduino-Code - Türschloss-System mit Passwort unter Verwendung eines Tastaturfeldes, eines elektromagnetischen Schlosses und einer LCD-Anzeige
/*
* Dieser Arduino Code wurde von newbiely.de entwickelt
* Dieser Arduino Code wird der Öffentlichkeit ohne jegliche Einschränkung zur Verfügung gestellt.
* Für vollständige Anleitungen und Schaltpläne besuchen Sie bitte:
* https://newbiely.de/tutorials/arduino/arduino-door-lock-system-using-password
*/
#include <Keypad.h>
#include <LiquidCrystal_I2C.h>
const int RELAY_PIN = A0; // the Arduino pin, which connects to the IN pin of relay
const int ROW_NUM = 4; //four rows
const int COLUMN_NUM = 4; //four columns
char keys[ROW_NUM][COLUMN_NUM] = {
{'1','2','3', 'A'},
{'4','5','6', 'B'},
{'7','8','9', 'C'},
{'*','0','#', 'D'}
};
byte pin_rows[ROW_NUM] = {9, 8, 7, 6}; //connect to the row pinouts of the keypad
byte pin_column[COLUMN_NUM] = {5, 4, 3, 2}; //connect to the column pinouts of the keypad
Keypad keypad = Keypad( makeKeymap(keys), pin_rows, pin_column, ROW_NUM, COLUMN_NUM );
LiquidCrystal_I2C lcd(0x27, 16, 2); // I2C address 0x27 (from DIYables LCD), 16 column and 2 rows
const String password_1 = "1234ABC"; // change your password here
const String password_2 = "5642CD"; // change your password here
const String password_3 = "4545B"; // change your password here
String input_password;
void setup(){
Serial.begin(9600);
input_password.reserve(32); // maximum input characters is 33, change if needed
pinMode(RELAY_PIN, OUTPUT); // initialize pin as an output.
digitalWrite(RELAY_PIN, HIGH); // lock the door
lcd.init(); // initialize the lcd
lcd.backlight();
}
void loop(){
char key = keypad.getKey();
if (key){
Serial.println(key);
if(key == '*') {
input_password = ""; // reset the input password
lcd.clear();
} else if(key == '#') {
lcd.clear();
if(input_password == password_1 || input_password == password_2 || input_password == password_3) {
Serial.println("password is correct");
lcd.setCursor(0, 0);
lcd.print("CORRECT!");
lcd.setCursor(0, 1);
lcd.print("DOOR UNLOCKED!");
digitalWrite(RELAY_PIN, LOW); // unlock the door for 20 seconds
delay(20000);
digitalWrite(RELAY_PIN, HIGH); // lock the door
} else {
Serial.println("password is incorrect, try again");
lcd.setCursor(0, 0);
lcd.print("INCORRECT!");
lcd.setCursor(0, 1);
lcd.print("ACCESS DENIED!");
}
input_password = ""; // reset the input password
} else {
if(input_password.length() == 0) {
lcd.clear();
}
input_password += key; // append new character to input password string
lcd.setCursor(input_password.length(), 0); // move cursor to new position
lcd.print('*'); // print * key as hiden character
}
}
}
※ Notiz:
Die I2C-Adresse des LCD-Displays kann je nach Hersteller variieren. Im Code verwenden wir 0x27, das vom Hersteller DIYables angegeben ist.
Schnelle Schritte
- Navigieren Sie zum Bibliotheken-Symbol in der linken Seitenleiste der Arduino IDE.
- Suchen Sie nach „LiquidCrystal I2C“, und finden Sie dann die LiquidCrystal_I2C-Bibliothek von Frank de Brabander.
- Klicken Sie auf die Schaltfläche Installieren, um die LiquidCrystal_I2C-Bibliothek zu installieren.
- Kopieren Sie den obigen Code und öffnen Sie ihn mit der Arduino IDE.
- Klicken Sie auf die Hochladen-Schaltfläche in der Arduino IDE, um den Code auf den Arduino hochzuladen.
- Bringen Sie die Ankerplatte nahe an den Elektromagneten.
- Geben Sie zuerst ein falsches Passwort ein und danach ein korrektes Passwort.
- Beobachten Sie die Anziehung zwischen der Ankerplatte und dem Elektromagneten über 20 Sekunden.
- Lesen Sie den Text auf dem LCD.
※ Notiz:
- In den obigen Codes haben wir zur Vereinfachung die Verzögerungsfunktion verwendet. Es ist besser, millis() statt delay() zu verwenden. Siehe Wie man millis() anstelle von delay() verwendet
- Sie können einen Piezo-Lautsprecher hinzufügen, um bei jedem Tastendruck des Tastaturfelds einen Piepton auszugeben.
- In den obigen Codes wird die Tür nach 20 Sekunden wieder verriegelt. Sie können sie durch einen Türsensor ersetzen. Die Tür wird verriegelt, wenn der Türsensor erkennt, dass die Tür vom Benutzer geschlossen ist.
- Im obigen Code sind die Passwörter fest codiert. In der Praxis sollte es möglich sein, Passwörter dynamisch über einen speziellen Modus hinzuzufügen, zu löschen oder zu ändern. Falls ja, sollten die Passwörter im EEPROM-Speicher gespeichert werden. Die Anzahl der Passwörter hängt von der Größe des EEPROM ab. Der Code wird komplizierter. Wenn Sie ein solches System bauen möchten, bieten wir einen Programmierdienst an. Bitte zögern Sie nicht, uns zu kontaktieren.
Video Tutorial
Wir erwägen die Erstellung von Video-Tutorials. Wenn Sie Video-Tutorials für wichtig halten, abonnieren Sie bitte unseren YouTube-Kanal , um uns zu motivieren, die Videos zu erstellen.