Arduino - LED - Blinken ohne Verzögerung
Stellen wir uns vor, Arduino müsste zwei Aufgaben erledigen: das Blinken der LED und das Prüfen des Zustands der Taste, die jederzeit gedrückt werden kann. Wenn wir die delay() Funktion verwenden (wie in einem vorherigen Tutorial beschrieben), könnte Arduino einige der Tastendrücke verpassen. Mit anderen Worten kann Arduino die zweite Aufgabe nicht vollständig erfüllen.
In diesem Tutorial lernen wir, wie Arduino eine LED blinkt und den Zustand des Knopfs überprüft, ohne einen Tastendruck zu verpassen.
Wir werden drei untenstehende Beispiele durchgehen und den Unterschied zwischen ihnen vergleichen.
- Arduino blinkt LED mithilfe der delay()-Funktion
- Arduino blinkt LED mithilfe der millis()-Funktion
- Arduino blinkt LED mithilfe der ezLED-Bibliothek
※ Notiz:
- Diese Methode dient nicht nur dem Blinken der LED und der Überprüfung des Zustands des Tasters. Im Allgemeinen ermöglicht diese Methode dem Arduino, mehrere Aufgaben gleichzeitig auszuführen, ohne sich gegenseitig zu blockieren.
- Dieses Tutorial bietet vertiefte Kenntnisse, die Ihnen helfen, das Funktionsprinzip zu verstehen. Um es einfacher zu machen, können Sie Arduino - LED-Bibliothek verwenden.
Erforderliche Hardware
Oder Sie können die folgenden Kits kaufen:
| 1 | × | DIYables STEM V3 Starter-Kit (Arduino enthalten) | |
| 1 | × | DIYables Sensor-Kit (30 Sensoren/Displays) | |
| 1 | × | DIYables Sensor-Kit (18 Sensoren/Displays) |
Offenlegung: Einige der in diesem Abschnitt bereitgestellten Links sind Amazon-Affiliate-Links. Wir können eine Provision für Käufe erhalten, die über diese Links getätigt werden, ohne zusätzliche Kosten für Sie. Wir schätzen Ihre Unterstützung.
Kaufhinweis: Um den Verdrahtungsprozess zu vereinfachen, empfehlen wir die Verwendung des LED Module, das mit einem eingebauten Widerstand geliefert wird.
Über LED und Taster
Wenn Sie nichts über LED und Taster wissen (Pinbelegung, wie sie funktionieren, wie man programmiert ...), informieren Sie sich in den folgenden Tutorials darüber:
Verdrahtungsdiagramm
Dieses Bild wurde mit Fritzing erstellt. Klicken Sie, um das Bild zu vergrößern.
Arduino-Code - Mit Verzögerung
/*
* Dieser Arduino Code wurde von newbiely.de entwickelt
* Dieser Arduino Code wird der Öffentlichkeit ohne jegliche Einschränkung zur Verfügung gestellt.
* Für vollständige Anleitungen und Schaltpläne besuchen Sie bitte:
* https://newbiely.de/tutorials/arduino/arduino-led-blink-without-delay
*/
// constants won't change:
const int LED_PIN = 3; // the number of the LED pin
const int BUTTON_PIN = 7; // the number of the button pin
const long BLINK_INTERVAL = 1000; // interval at which to blink LED (milliseconds)
// Variables will change:
int ledState = LOW; // ledState used to set the LED
int previousButtonState = LOW; // will store last time button was updated
void setup() {
Serial.begin(9600);
// set the digital pin as output:
pinMode(LED_PIN, OUTPUT);
// set the digital pin as an input:
pinMode(BUTTON_PIN, INPUT);
}
void loop() {
// if the LED is off turn it on and vice-versa:
ledState = (ledState == LOW) ? HIGH : LOW;
// set the LED with the ledState of the variable:
digitalWrite(LED_PIN, ledState);
delay(BLINK_INTERVAL); // If button is pressed during this time, Arduino CANNOT detect
int currentButtonState = digitalRead(BUTTON_PIN);
if(currentButtonState != previousButtonState) {
// print out the state of the button:
Serial.println(currentButtonState);
// save the last state of button
previousButtonState = currentButtonState;
}
// DO OTHER WORKS HERE
}
Schnelle Schritte
- Verbinde Arduino über ein USB-Kabel mit dem PC.
- Öffne die Arduino IDE, wähle das richtige Board und den richtigen Port aus.
- Kopiere den obigen Code und öffne ihn in der Arduino IDE.
- Klicke auf die Schaltfläche Hochladen in der Arduino IDE, um den Code auf Arduino hochzuladen.
- Seriellen Monitor öffnen
- Drücke den Knopf viermal
- Sieh die LED: Die LED wechselt jede Sekunde zwischen EIN und AUS
- Sieh die Ausgabe im seriellen Monitor
COM6
1
0
Autoscroll
Clear output
9600 baud
Newline
- Im Serial Monitor wurden einige Drückvorgänge verpasst. Das liegt daran, dass während der Verzögerungszeit der Arduino nichts tun kann. Daher kann es das Drücken eines Knopfes nicht erkennen.
Arduino-Code - Ohne Verzögerung
/*
* Dieser Arduino Code wurde von newbiely.de entwickelt
* Dieser Arduino Code wird der Öffentlichkeit ohne jegliche Einschränkung zur Verfügung gestellt.
* Für vollständige Anleitungen und Schaltpläne besuchen Sie bitte:
* https://newbiely.de/tutorials/arduino/arduino-led-blink-without-delay
*/
// constants won't change:
const int LED_PIN = 3; // the number of the LED pin
const int BUTTON_PIN = 7; // the number of the button pin
const long BLINK_INTERVAL = 1000; // interval at which to blink LED (milliseconds)
// Variables will change:
int ledState = LOW; // ledState used to set the LED
int previousButtonState = LOW; // will store last time button was updated
unsigned long previousMillis = 0; // will store last time LED was updated
void setup() {
Serial.begin(9600);
// set the digital pin as output:
pinMode(LED_PIN, OUTPUT);
// set the digital pin as an input:
pinMode(BUTTON_PIN, INPUT);
}
void loop() {
// check to see if it's time to blink the LED; that is, if the difference
// between the current time and last time you blinked the LED is bigger than
// the interval at which you want to blink the LED.
unsigned long currentMillis = millis();
if (currentMillis - previousMillis >= BLINK_INTERVAL) {
// if the LED is off turn it on and vice-versa:
ledState = (ledState == LOW) ? HIGH : LOW;
// set the LED with the ledState of the variable:
digitalWrite(LED_PIN, ledState);
// save the last time you blinked the LED
previousMillis = currentMillis;
}
// check button state's change
int currentButtonState = digitalRead(BUTTON_PIN);
if(currentButtonState != previousButtonState) {
// print out the state of the button:
Serial.println(currentButtonState);
// save the last state of button
previousButtonState = currentButtonState;
}
// DO OTHER WORKS HERE
}
Schnelle Schritte
- Führe den obigen Code aus und drücke den Knopf viermal
- Sieh dir die LED an: Die LED wechselt periodisch jede Sekunde zwischen EIN und AUS
- Sieh dir die Ausgabe im seriellen Monitor an
COM6
1
0
1
0
1
0
1
0
Autoscroll
Clear output
9600 baud
Newline
- Alle dringenden Ereignisse wurden erkannt.
Code-Erklärung
Sie finden die Erklärung in den Kommentaren des oben gezeigten Arduino-Codes.
Weitere Aufgaben hinzufügen
Der untenstehende Code blinkt zwei LEDs mit unterschiedlichen Intervallen und überprüft den Zustand des Tasters.
/*
* Dieser Arduino Code wurde von newbiely.de entwickelt
* Dieser Arduino Code wird der Öffentlichkeit ohne jegliche Einschränkung zur Verfügung gestellt.
* Für vollständige Anleitungen und Schaltpläne besuchen Sie bitte:
* https://newbiely.de/tutorials/arduino/arduino-led-blink-without-delay
*/
// constants won't change:
const int LED_PIN_1 = 3; // the number of the LED 1 pin
const int LED_PIN_2 = LED_BUILTIN; // the number of the LED 2 pin
const int BUTTON_PIN = 7; // the number of the button pin
const long BLINK_INTERVAL_1 = 1000; // interval at which to blink LED 1 (milliseconds)
const long BLINK_INTERVAL_2 = 500; // interval at which to blink LED 2 (milliseconds)
// Variables will change:
int ledState_1 = LOW; // ledState used to set the LED 1
int ledState_2 = LOW; // ledState used to set the LED 2
int previousButtonState = LOW; // will store last time button was updated
unsigned long previousMillis_1 = 0; // will store last time LED 1 was updated
unsigned long previousMillis_2 = 0; // will store last time LED 2 was updated
void setup() {
Serial.begin(9600);
// set the digital pin as output:
pinMode(LED_PIN_1, OUTPUT);
pinMode(LED_PIN_2, OUTPUT);
// set the digital pin as an input:
pinMode(BUTTON_PIN, INPUT);
}
void loop() {
unsigned long currentMillis = millis();
// check to see if it's time to blink the LED 1
if (currentMillis - previousMillis_1 >= BLINK_INTERVAL_1) {
// if the LED is off turn it on and vice-versa:
ledState_1 = (ledState_1 == LOW) ? HIGH : LOW;
// set the LED with the ledState of the variable:
digitalWrite(LED_PIN_1, ledState_1);
// save the last time you blinked the LED
previousMillis_1 = currentMillis;
}
// check to see if it's time to blink the LED 2
if (currentMillis - previousMillis_2 >= BLINK_INTERVAL_2) {
// if the LED is off turn it on and vice-versa:
ledState_2 = (ledState_2 == LOW) ? HIGH : LOW;
// set the LED with the ledState of the variable:
digitalWrite(LED_PIN_2, ledState_2);
// save the last time you blinked the LED
previousMillis_2 = currentMillis;
}
// check button state's change
int currentButtonState = digitalRead(BUTTON_PIN);
if(currentButtonState != previousButtonState) {
// print out the state of the button:
Serial.println(currentButtonState);
// save the last state of button
previousButtonState = currentButtonState;
}
// DO OTHER WORKS HERE
}
Video Tutorial
Wir erwägen die Erstellung von Video-Tutorials. Wenn Sie Video-Tutorials für wichtig halten, abonnieren Sie bitte unseren YouTube-Kanal , um uns zu motivieren, die Videos zu erstellen.
Erweiterbarkeit
Diese Methode ermöglicht es dem Arduino, mehrere Aufgaben gleichzeitig auszuführen, ohne dass sie sich gegenseitig blockieren. Zum Beispiel das Senden einer Anfrage an das Internet und das Warten auf die Antwort; während des Wartens auf die Antwort blinken einige LED-Indikatoren und der Abbruchknopf wird überwacht.